Yff Conjecture

Author

Eric W. Weisstein
September 26, 2007

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Trigonometry/YffConjecture.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/YffConjecture.html.

©2007 Wolfram Research, Inc. except for portions noted otherwise

Monte Carlo

omega[a_List]:=ArcCot[Total[Cot[a]]]

Timing[diffs=Times@@#-8omega[#]^3&/@(vals=Table[{a=Random[Real,{0,Pi}],b=Random[Real,{0,Pi-a}],Pi-a-b},{200000}]);
]

Through[{Min,Max}[diffs]]

Sort/@(vals[[Position[diffs,#][[1,1]]]]&/@Take[Sort[diffs],-10])

Minimum

With[{ϵ=10^-6},NMinimize[{a b c-8ArcCot[Cot[a]+Cot[b]+Cot[c]]^3,
ϵ<a<Pi,ϵ<b<Pi,ϵ<c<Pi,a+b+c==Pi},{a,b,c},WorkingPrecision->20]]

Maximum

3 Variables

With[{ϵ=10^-6},NMaximize[{a b c-8ArcCot[Cot[a]+Cot[b]+Cot[c]]^3,
ϵ<a<Pi&&ϵ<b<Pi&&ϵ<c<Pi&&a+b+c==Pi},{a,b,c},WorkingPrecision->20]]

TimeConstrained[Maximize[{a b c-8ArcCot[Cot[a]+Cot[b]+Cot[c]]^3,
0<a<Pi&&0<b<Pi&&0<c<Pi&&a+b+c==Pi},{a,b,c}],120]//Timing

The Lagrange multiplier methods yields the following Reduce problem:

Reduce[-a-b-c+Pi==0&&-(b*c)+(24*ArcCot[Cot[a]+Cot[b]+Cot[c]]^2*Csc[a]^2)/(1+(Cot[a]+Cot[b]+Cot[c])^2)-L==0&&-(a*c)+(24*ArcCot[Cot[a]+Cot[b]+Cot[c]]^2*Csc[b]^2)/(1+(Cot[a]+Cot[b]+Cot[c])^2)-L==0&&-(a*b)+(24*ArcCot[Cot[a]+Cot[b]+Cot[c]]^2*Csc[c]^2)/(1+(Cot[a]+Cot[b]+Cot[c])^2)-L==0&&0<a<Pi&&0<b<Pi&&0<c<Pi,{a,b,c,L},Reals]

which in turn, after polynomialization, gives a CAD call with 5 variables and huge polynomials of degree at least 14.  So eliminate one of the variables by hand.

Two Variables

NMaximize[{a b(Pi-a-b)-8ArcCot[Cot[a]+Cot[b]+Cot[(Pi-a-b)]]^3,
0<a<Pi&&0<b<Pi},{a,b},WorkingPrecision->20]//Timing

Maximize[{a b(Pi-a-b)-8ArcCot[Cot[a]+Cot[b]+Cot[(Pi-a-b)]]^3,
0<a<Pi&&0<b<Pi},{a,b}]//Timing

One Variable

Eliminate two by hand and symmetry

With[{b=a,c=π-2a},a b c-8ArcCot[Cot[a]+Cot[b]+Cot[c]]^3]

FullSimplify[%]

TimeConstrained[Maximize[{(a^2) (-2 a+π)-8 ((ArcCot[2 Cot[a]-Cot[2 a]])^3),a>0},a],60]//Timing

TimeConstrained[Maximize[{(a^2) (-2 a+π)-8 ((ArcCot[2 Cot[a]-Cot[2 a]])^3),1<a<3/2},a],60]//Timing

TimeConstrained[Maximize[{(a^2) (-2 a+π)-8 ((ArcCot[2 Cot[a]-Cot[2 a]])^3),11/10<a<3/2},a],60]//Timing

N[%]

Plot[(a^2) (-2 a+π)-8 ((ArcCot[(1/2) (3 Cot[a]+Tan[a])])^3),{a,0,π},PlotStyle->Red]

D[(a^2) (-2 a+π)-8 ((ArcCot[2 Cot[a]-Cot[2 a]])^3),a]

FullSimplify[%]

FindRoot[2 a (-3 a+π)-((48 ((ArcCot[(1/2) (3 Cot[a]+Tan[a])])^2) (1+2 Cos[2 a]))/(5+4 Cos[2 a])),{a,1.2,1.5},WorkingPrecision->20]

Solve[(a^2) (-2 a+π)-8 ((ArcCot[2 Cot[a]-Cot[2 a]])^3)==0,a]

Reduce[2 a (-3 a+π)-((48 ((ArcCot[(1/2) (3 Cot[a]+Tan[a])])^2) (1+2 Cos[2 a]))/(5+4 Cos[2 a]))==0&&11/10<a<3/2,a,Reals]

FullSimplify[%]

With[{a= Root[{-24 ((ArcCot[(1/2) (3 Cot[#1]+Tan[#1])])^2)-48 ((ArcCot[(1/2) (3 Cot[#1]+Tan[#1])])^2) Cos[2 #1]+5 π #1+4 π Cos[2 #1] #1-15 ((#1)^2)-12 Cos[2 #1] ((#1)^2)&,1.4093562703546197036113629087423591081712145506414867975373`30.102999566398122}]},(a^2) (-2 a+π)-8 ((ArcCot[2 Cot[a]-Cot[2 a]])^3)]

FullSimplify[%]

N[%,20]