Unit Circle

Author

Eric W. Weisstein
April 17, 2024

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Trigonometry/UnitCircle.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/UnitCircle.html.

©2024 Wolfram Research, Inc. except for portions noted otherwise

Figures

Unit circle

With[{θ=60Degree},With[{pt=ReIm[Exp[I θ]]},Graphics[{Circle[],Arrowheads[.04{-1,1}],Arrow[{{0,0},pt}],Text[Style[" 1 ",18],pt/2,Background->White]}]]]

Unit circle trigonometry

From Christopher Stover
June 2014

Module[{θ=30°,p},
p=ReIm[Exp[I θ]];
Graphics[{
Text["θ",.25Through[{Cos,Sin}[θ/2]]],
Text[1,p/2+{0,.1}],
Text[Row[{"cos"," ","θ"}],{.55,.07}],
Text[Row[{"sin"," ","θ"}],{p[[1]]-.02,p[[2]]/2},{1,0}],
Circle[],
{Green,Thickness[.005],Circle[{0,0},1,{0,θ}]},
Red,PointSize[.03],Point[p],
Text[P==Row[{"(","cos"," ","θ",", ","sin"," ","θ",")"}],1.1p,{-1,0}],
Line[{{0,0},{p[[1]],0},p,{0,0}}]
},
Axes->True,AxesStyle->Directive[Arrowheads[{-1,1}.04]],
Ticks->None,
AxesLabel->{x,y},
BaseStyle->14
]
]

Angles

From Christopher Stover
June 2014

With[{c=Gray,cs=ReIm[Exp[I #]]&},
Graphics[{
{Black,Thick,Circle[{0,0},1]},
{c,Thick,Line[{0#,#}&/@Table[cs[k],{k,{π/3,3π/4,7π/6,11π/6}}]]},
{c,Rotate[Text[" π/3 radians ",0.5cs[π/3],Background->White],π/3]},
{c,Rotate[Text[" 3π/4 radians ",0.5cs[3π/4],Background->White],-π/4]},
{c,Rotate[Text[" 7π/6 radians ",0.5cs[7π/6],Background->White],π/6]},
{c,Rotate[Text[" 11π/6 radians ",0.5cs[11π/6],Background->White],-π/6]},
{PointSize[0.025],Table[Point[cs[k]],{k,{3π/4,π/3,11π/6,7π/6}}]},
{Text[Style["A",Italic],1.1cs[π/3]]},
{Text[Style["B",Italic],1.1cs[3π/4]]},
{Text[Style["C",Italic],1.1cs[7π/6]]},
{Text[Style["D",Italic],1.1cs[11π/6]]}
},
Axes->True,AxesStyle->Arrowheads[{-1,1}.04],Ticks->None,AxesLabel->{x,y},BaseStyle->14
]]

Complex plane

With[{style=Directive[14,Black,FontFamily->"Times"]},ComplexContourPlot[Abs[z]==1,{z,1},Epilog->Disk[{0,0},.02],ContourStyle->Black,Frame->False,Axes->True,AxesStyle->Arrowheads[{-1,1}.04],PlotLabel->Abs[z]==1,BaseStyle->style,LabelStyle->style,AxesLabel->{x,y}]]