Trigonemetric Addition Formulas

Author

Eric W. Weisstein
January 2, 2009

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Trigonometry/TrigonometricAdditionFormulas.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/TrigonometricAdditionFormulas.html.

©2009 Wolfram Research, Inc. except for portions noted otherwise

Identities

FullSimplify[{Sin[p]+Sin[q]-2 Sin[(p+q)/2] Cos[(p-q)/2],
Sin[p]-Sin[q]-2 Sin[(p-q)/2] Cos[(p+q)/2],
Cos[p]+Cos[q]-2 Cos[(p+q)/2] Cos[(p-q)/2],
Cos[p]-Cos[q]-(-2 Sin[(p-q)/2] Sin[(p+q)/2])
}]

Angle Addition Formulas

soln=FullSimplify[Solve[{s==(sb+sa/c)/(ca+sa s/c),
c==cb/(ca+sa s/c)} ,
{c,s}]]

Denominator of Sin[a+b]

Collect[Expand[(ca cb+sa sb)(sa cb+sb ca)],{ca sa,cb sb}]

% /. {ca^2+sa^2->1,cb^2+sb^2->1}

Denominator of Cos[a+b]

Expand[(ca cb+sa sb)(ca cb-sa sb)]

Expand[(ca cb+sa sb)(ca cb-sa sb) /.{ ca->Sqrt[1-sa^2],cb->Sqrt[1-sb^2]}]

% /. sb->Sqrt[1-cb^2]

%% /. sa->Sqrt[1-ca^2]

Check

Simplify[soln/.{cb->Cos[b],ca->Cos[a],sa->Sin[a],sb->Sin[b]}]

Multiple-Angle Formulas

Recurrence

FullSimplify[Sin[n x]-(2 Sin[(n-1)x]Cos[x]-Sin[(n-2)x])]

FullSimplify[Cos[n x]-(2 Cos[(n-1)x]Cos[x]-Cos[(n-2)x])]

FullSimplify[Tan[n x]-(Tan[(n-1)x]+Tan[x])/(1-Tan[x]Tan[(n-1)x])]

sin(n x)==(∑_(k=0)^n)(Binomial[n, k]) sin((1/2) π (n-k)) (cos^k)(x) (sin^(n-k))(x)

Sum[Binomial[n,k]Cos[x]^k Sin[x]^(n-k) Sin[(n-k)Pi/2],{k,0,n}]

FullSimplify[%,n∈Integers]

sin[n_,x_]:=Module[{k},
Sum[Binomial[n,k]Cos[x]^k Sin[x]^(n-k) Sin[(n-k)Pi/2],{k,0,n}]
]

FullSimplify[Table[sin[n,x]-Sin[n x],{n,10}]]

Table[TrigExpand[Sin[n x]],{n,5}]//ColumnForm

Table[sin[n,x]-TrigExpand[Sin[n x]],{n,5}]

Bromwich

FullSimplify[FunctionExpand[Product[(n^2-(2k-1)^2),{k,l}] ,(l|n)∈Integers&&0<l<n],(l|n)∈Integers&&0<l<n]

f[n_]:=n x+Sum[n(-1)^l Product[(n^2-(2k-1)^2),{k,l}] x^(2l+1)/(2l+1)!,{l,n}]

n x+Sum[n(-1)^l Product[(n^2-(2k-1)^2),{k,l}] x^(2l+1)/(2l+1)!,{l,n}]

FullSimplify[%,n∈Integers&&n>0]

FullSimplify[FunctionExpand[Product[(n^2-(2k-1)^2),{k,l}]],{n∈Integers}]

f[11]

Odd multiples of n in terms of Sin[x]

Table[Expand[TrigExpand[Sin[n x]]/.Cos[x]->Sqrt[1-Sin[x]^2]],{n,1,13,2}]//ColumnForm

FullSimplify[Table[(-1)^((n-1)/2) ChebyshevT[n,Sin[x]]-Sin[n x],{n,1,13,2}]]

Sin[nx] for n even in terms of Sin[x]

Table[Cos[x]Expand[TrigExpand[Sin[n x]/Cos[x]]/.Cos[x]->Sqrt[1-Sin[x]^2]],{n,2,13,2}]//ColumnForm

FullSimplify[Table[(-1)^(1+n/2) ChebyshevU[n-1,Sin[x]]Cos[x]-Sin[n x],{n,2,13,2}]]

Sin[nx] for n odd in terms of Cos[x]

Table[Sin[x]Expand[TrigExpand[Sin[n x]/Sin[x]]/.Sin[x]->Sqrt[1-Cos[x]^2]],{n,1,13,2}]//ColumnForm

FullSimplify[Table[ChebyshevU[n-1,Cos[x]]Sin[x]-Sin[n x],{n,1,15,2}]]

Sin[nx] in terms of Cos[x]

Table[Sin[x]Expand[TrigExpand[Sin[n x]/Sin[x]]/.Sin[x]->Sqrt[1-Cos[x]^2]],{n,13}]//ColumnForm

FullSimplify[Table[ChebyshevU[n-1,Cos[x]]Sin[x]-Sin[n x],{n,13}]]

cos(n x)==(∑_(k=0)^n)(Binomial[n, k]) cos((1/2) π (n-k)) (cos^k)(x) (sin^(n-k))(x)

Sum[Binomial[n,k]Cos[x]^k Sin[x]^(n-k)Cos[(n-k)Pi/2],{k,0,n}]

FullSimplify[%,n∈Integers&&n>0]

cos[n_,x_]:=Module[{k},
Sum[Binomial[n,k]Cos[x]^k Sin[x]^(n-k)Cos[(n-k)Pi/2],{k,0,n}]
]

FullSimplify[Table[cos[n,x]-Cos[n x],{n,10}]]

Table[cos[n,x],{n,5}]//ColumnForm

Cos[nx] in terms of Cos[x]

Table[Expand[TrigExpand[Cos[n x]]/.Sin[x]->Sqrt[1-Cos[x]^2]],{n,5}]//ColumnForm

FullSimplify[Table[ChebyshevT[n,Cos[x]]-Cos[n x],{n,13}]]

Cos[nx] for odd n in terms of Sin[x]

Table[Cos[x]Expand[TrigExpand[Cos[n x]/Cos[x]]/.Cos[x]->Sqrt[1-Sin[x]^2]],{n,1,13,2}]//ColumnForm

FullSimplify[Table[Cos[x](-1)^((n-1)/2)ChebyshevU[n-1,Sin[x]]-Cos[n x],{n,1,13,2}]]

Cos[nx] for odd n in terms of Sin[x]

Table[Expand[TrigExpand[Cos[n x]]/.Cos[x]->Sqrt[1-Sin[x]^2]],{n,2,13,2}]//ColumnForm

FullSimplify[Table[(-1)^(n/2)ChebyshevT[n,Sin[x]]-Cos[n x],{n,2,13,2}]]