Multiple-Angle Formulas

Author

Eric W. Weisstein
January 11, 2003

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Trigonometry/Multiple-AngleFormulas.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/Multiple-AngleFormulas.html.

©2005 Wolfram Research, Inc. except for portions noted otherwise

sin(n x)

(sines=TrigExpand/@Table[Sin[n x],{n,2,5}])//ColumnForm

Binomial Sum

(sines2=Table[Sum[Binomial[n,k]Cos[x]^k Sin[x]^(n-k)Sin[(n-k)Pi/2],{k,0,n}],{n,2,5}])//ColumnForm

Simplify[sines-sines2]

Chebyshev of Sin

(sines2=Table[Switch[n,
_?OddQ,(((-1))^((n-1)/2))ChebyshevT[n,Sin[x]],
_?EvenQ,(((-1))^(n/2-1)) Cos[x]ChebyshevU[n-1,Sin[x]]
],{n,2,5}])//ColumnForm

FullSimplify[sines-sines2]

Chebyshev of Cos

(sines2=Table[Sin[x]ChebyshevU[n-1,Cos[x]],{n,2,5}])//ColumnForm

FullSimplify[sines-sines2]

Recurrence

sin[0]:=0
sin[x]:=Sin[x]
sin[n_ x]:=2 sin[(n-1)x]Cos[x]-sin[(n-2)x]

(sines2=Expand/@Table[sin[n x],{n,2,5}])//ColumnForm

Simplify[sines-sines2]

cos(n x)

(cosines=TrigExpand/@Table[Cos[n x],{n,2,5}])//ColumnForm

Binomial Sum

(cosines2=Table[Sum[Binomial[n,k]Cos[x]^k Sin[x]^(n-k)Cos[(n-k)Pi/2],{k,0,n}],{n,2,5}])//ColumnForm

cosines-cosines2

FullSimplify[Sum[Binomial[n,k]Cos[x]^k Sin[x]^(n-k)Cos[(n-k)Pi/2],{k,0,n}],n∈Integers]

Chebyshev Sin

(cosines2=Table[Switch[n,
_?OddQ,(((-1))^((n-1)/2))Cos[x]ChebyshevU[n-1,Sin[x]],
_?EvenQ,(((-1))^(n/2)) ChebyshevT[n,Sin[x]]
],{n,2,5}])//ColumnForm

Simplify[cosines-cosines2]

Chebyshev Cos

(cosines2=Table[ChebyshevT[n,Cos[x]],{n,2,5}])//ColumnForm

Simplify[cosines-cosines2]

Recurrence

cos[0]:=1
cos[x]:=Cos[x]
cos[n_ x]:=2 cos[(n-1)x]Cos[x]-cos[(n-2)x]

(cosines2=Expand/@Table[cos[n x],{n,2,5}])//ColumnForm

Simplify[cosines-cosines2]

tan(n x)

(tangents=TrigExpand/@Table[Tan[n x],{n,2,5}])//ColumnForm

Recurrence

tan[x]:=Tan[x]
tan[n_ x]:=(tan[(n-1)x]+tan[x])/(1-tan[(n-1)x]tan[x])

FullSimplify[(Tan[(n-1)x]+Tan[x])/(1-Tan[(n-1)x]Tan[x])]

(tangents2=Cancel/@Table[tan[n x],{n,2,5}])//ColumnForm

Simplify[tangents-tangents2]