Pseudosphere

Author

Eric W. Weisstein
June 10, 2014

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Surfaces/Pseudosphere.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/Pseudosphere.html.

©2014 Wolfram Research, Inc. except for portions noted otherwise

Plot

Parametrization 1

V5

ParametricPlot3D[{Sech[u]Cos[v],Sech[u]Sin[v],u-Tanh[u]},{u,-3.5,3.5},{v,0,2 Pi},Boxed->False,Axes->False,ImageSize->200,PlotRange->All]

V6

g=ParametricPlot3D[{Sech[u]Cos[v],Sech[u]Sin[v],u-Tanh[u]},{u,-3.5,3.5},{v,0,2 Pi},Boxed->False,Axes->False,ImageSize->200,PlotRange->All]

Parametrization 2

g=ParametricPlot3D[{Sech[u]Cos[u+v],Sech[u]Sin[u+v],u-Tanh[u]},{u,-3.5,3.5},{v,0,2 Pi},Boxed->False,Axes->False,ImageSize->200,PlotRange->All]

Parametrization 3

g=ParametricPlot3D[{Cos[u]Sin[v],Sin[u]Sin[v],Cos[v]+Log[Tan[(v/2)]]},{u,0,2π},{v,.15,3.},Boxed->False,Axes->False,PlotRange->All]

Parametrization 4

V4.2

FullSimplify[Integrate[(Sqrt[1-Exp[-2t]]),{t,0,v},Assumptions->v>0],v>0]

Integrate[(Sqrt[1-Exp[2t]]),{t,0,v},Assumptions->v<0]//FullSimplify

ψ[v_]:=Piecewise[
{
{-(E^(-v)) (Sqrt[-1+(E^(2 v))])+Log[(E^v)+(Sqrt[-1+(E^(2 v))])],v≥0},{(Sqrt[1-(E^(2 v))])-ArcTanh[(Sqrt[1-(E^(2 v))])],v<0}
}]
φ[v_]:=Piecewise[
{
{Exp[-v],v≥0},
{Exp[v],v<0}
}]

V6.1

Integrate[(Sqrt[1-Exp[-2t]]),{t,0,v},Assumptions->v>0]//FullSimplify

Integrate[(Sqrt[1-Exp[2t]]),{t,0,v},Assumptions->v<0]//FullSimplify

ψ[v_]:=Piecewise[
{
{-(E^(-v)) (Sqrt[-1+(E^(2 v))])+Log[(E^v)+(Sqrt[-1+(E^(2 v))])],v≥0},{(E^v) (Sqrt[-1+(E^(-2 v))])+I π+v-Log[-1-(Sqrt[1-(E^(2 v))])],v<0}
}]
φ[v_]:=Piecewise[
{
{Exp[-v],v≥0},
{Exp[v],v<0}
}]

Plug in

g=ParametricPlot3D[{φ[v]Cos[u],φ[v]Sin[u],ψ[v]},{u,0,2π},{v,-3,3},Boxed->False,Axes->False]

LiveGraphics3D

<<Utilities`LiveGraphics3D`

WriteLiveForm["pseudosp.m",g]

Equations

Eliminate[Thread[{x,y,z}==a{Sech[u]Cos[v],Sech[u]Sin[v],u-Tanh[u]}],{u,v}]

a^2FullSimplify[(Sech[u]Cos[v])^2+(Sech[u]Sin[v])^2]

Solve[x^2+y^2==a^2 Sech[u]^2,u]

FullSimplify[a(ArcSech[((Sqrt[(x^2)+(y^2)])/a)]-Tanh[ArcSech[((Sqrt[(x^2)+(y^2)])/a)]]),(x|y)∈Reals&&a>0]

FullSimplify[z^2-(((a ArcSech[((Sqrt[(x^2)+(y^2)])/a)]-(Sqrt[(a^2)-(x^2)-(y^2)])))^2)/.Thread[{x,y,z}->a{Sech[u]Cos[v],Sech[u]Sin[v],u-Tanh[u]}],a>0&&u>0]

Block[{a=1},ContourPlot3D[z^2==(((a ArcSech[((Sqrt[(x^2)+(y^2)])/a)]-(Sqrt[(a^2)-(x^2)-(y^2)])))^2),{x,-1,1},{y,-1,1},{z,-3,3},BoxRatios->Automatic]]

Curvatures

Curvatures[a{Sech[u]Cos[v],Sech[u]Sin[v],u-Tanh[u]},{u,v},FullSimplify[#,u>0&&0<v<2π&&a>0]&]

FullSimplify[PrincipalCurvatures[a{Sech[u]Cos[v],Sech[u]Sin[v],u-Tanh[u]},{u,v}],u>0&&0<v<2π&&a>0]

GaussianCurvature[z^2-(((a ArcSech[((Sqrt[(x^2)+(y^2)])/a)]-(Sqrt[(a^2)-(x^2)-(y^2)])))^2),{x,y,z}]

Surface Area

Parameterization 1

Simplify[AreaElement[{Sech[u]Cos[v],Sech[u]Sin[v],u-Tanh[u]},{u,v}],u>0]

2Integrate[Sech[u] Tanh[u],{u,0,Infinity},{v,0,2Pi}]

Parameterization 1

Simplify[AreaElement[{Sech[u]Cos[u+v],Sech[u]Sin[u+v],u-Tanh[u]},{u,v}],u>0]

2Integrate[Sech[u] Tanh[u],{u,0,Infinity},{v,0,2Pi}]

Parameterization 3

Simplify[AreaElement[{Cos[u]Sin[v],Sin[u]Sin[v],Cos[v]+Log[Tan[(v/2)]]},{u,v}],v>0]

Plot[Abs[Cos[v]],{v,0,π}]

Integrate[Abs[Cos[v]],{u,0,2π},{v,0,π}]

Parameterization 4

Use the V4.1 integral result

FullSimplify[AreaElement[{φ[v]Cos[u],φ[v]Sin[u],ψ[v]},{u,v}],v∈Reals&&0<u<2π]

Integrate[Piecewise[{{E^(-v), v > 0}, {E^v, v < 0}}],{u,0,2π},{v,-∞,∞}]

Volume

FullSimplify[Norm[{Sech[u]Cos[v],Sech[u]Sin[v]}]^2,u>0&&0<v<2π]

Solve[{r==Sech[u],z==u-Tanh[u]},r,u]

Limit[u-Tanh[u],u->#]&/@{-∞,0,∞}

D[u-Tanh[u],u]//FullSimplify

FullSimplify[Sech[u]^2Tanh[u]^2,u>0]

π Integrate[((Sech[u])^2) ((Tanh[u])^2),{u,-∞,∞}]

RegionPlot3D[z^2-(((ArcSech[(Sqrt[(x^2)+(y^2)])]-(Sqrt[1-(x^2)-(y^2)])))^2)<0,{x,-1,1},{y,-1,1},{z,-5,5}]

RegionPlot3D[z^2-(((ArcSech[(Sqrt[(x^2)+(y^2)])]-(Sqrt[1-(x^2)-(y^2)])))^2)<0,{x,-1,1},{y,-1,1},{z,-5,5},WorkingPrecision->20]

RegionPlot3D[Chop[z^2-(((ArcSech[(Sqrt[(x^2)+(y^2)])]-(Sqrt[1-(x^2)-(y^2)])))^2)]<0,{x,-1,1},{y,-1,1},{z,-2,2},BoxRatios->Automatic]

NIntegrate[Boole[z^2-(((ArcSech[(Sqrt[(x^2)+(y^2)])]-(Sqrt[1-(x^2)-(y^2)])))^2)<0],{x,-1,1},{y,-1,1},{z,-2,2},WorkingPrecision->20]

NIntegrate[Boole[Chop[z^2-(((ArcSech[(Sqrt[(x^2)+(y^2)])]-(Sqrt[1-(x^2)-(y^2)])))^2)]<0],{x,-1,1},{y,-1,1},{z,-3,3},SingularityDepth->20,WorkingPrecision->50]

2π/3.

Integrate[Boole[z^2-(((ArcSech[(Sqrt[(x^2)+(y^2)])]-(Sqrt[1-(x^2)-(y^2)])))^2)<0],{x,-1,1},{y,-1,1},{z,-∞,∞}]//Timing

Integrate[Boole[z^2-(((ArcSech[(Sqrt[(x^2)+(y^2)])]-(Sqrt[1-(x^2)-(y^2)])))^2)<0],{z,-∞,∞},{x,-1,1},{y,-1,1}]//Timing

Metric Properties

Metric Tensor

MetricTensor[a{Sech[u]Cos[v],Sech[u]Sin[v],u-Tanh[u]},{u,v}]//FullSimplify

Christoffel Symbol of the Second Kind

FullSimplify[ChristoffelSymbols[a{Sech[u]Cos[v],Sech[u]Sin[v],u-Tanh[u]},{u,v}],a>0&&u>0]

Vector Properties

eqn=a{Sech[u]Cos[v],Sech[u]Sin[v],u-Tanh[u]};
rules={Abs[x_]^(n_/;Mod[n,2]==0):>x^n};
assum=a>0&&u∈Reals&&0<v<2π;

Vector Length

Assuming[assum,FullSimplify[Norm[eqn]/.rules]]

Normal Vector

Assuming[assum,FullSimplify[NormalVector[eqn,{u,v}]/.rules]]