Elliptic Cylinder

Author

Eric W. Weisstein
July 22, 2014

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Surfaces/EllipticCylinder.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/EllipticCylinder.html.

©2014 Wolfram Research, Inc. except for portions noted otherwise

Initialization

Definitions

ineq=x^2/a^2+y^2/b^2≤1&&-h/2≤z≤h/2;

reg=ImplicitRegion[ineq,{x,y,z}];

assum=a>0&&b>0&&h>0;

Graphic

Diagram

Show[SolidData["SolidEllipticalCylinder","Image"],ImageSize->Small]

DiscretizeRegion

Block[{a=1,b=1/2,h=1},Show[DiscretizeRegion[reg],ImageSize->Small]]

Block[{a=1,b=.5,h=1},RegionPlot3D[ineq,{x,-a,a},{y,-b,b},{z,-h/2,h/2},Mesh->False,Boxed->False,BoxRatios->Automatic,Axes->None,ImageSize->Small]]

Eric’s package

cyl1=Show[EllipticCylinder[1.5,2,30,Caps->False]]

cyl2=Show[DropInnerPolygons[EllipticCylinder[1.5,2.,30]]]

LiveGraphics3D

<<Utilities`LiveGraphics3D`

WriteLiveForm["ellcyl1.m",cyl1]

WriteLiveForm["ellcyl2.m",cyl2]

Equations

GroebnerBasis[Append[Thread[{x,y,z}=={a Cos[v],b Sin[v],u}],Cos[v]^2+Sin[v]^2==1],{x,y,z},{u,Cos[v],Sin[v]},MonomialOrder->EliminationOrder]

Numerator[Together[((x^2)/(a^2))+((y^2)/(b^2))-1]]

Properties

Area Element

AreaElement[{a Cos[u],b Sin[u],v},{u,v}]

Centroid

Integrate

(1/(a b h π))Integrate[{x,y,z}Boole[x^2/a^2+y^2/b^2<1&&-h/2<z<h/2],{x,-∞,∞},{y,-∞,∞},{z,-∞,∞},Assumptions->a>0&&b>0&&h>0]//Timing

RegionCentroid

Assuming[assum,RegionCentroid[reg]]

Fundamental Forms

Curvatures[{a Cos[u],b Sin[u],v},{u,v},FullSimplify]

FullSimplify[PrincipalCurvatures[{a Cos[u],b Sin[u],v},{u,v}],a>0&&b>0&&(u|v)∈Reals]

Inertia Tensor

InertiaTensor[{x,y,z}]

(i=With[{ρ=(M/(π a b h))},
ρ Integrate[InertiaTensor[{x,y,z}]Boole[x^2/a^2+y^2/b^2<1&&-h/2<z<h/2],
{x,-∞,∞},{y,-∞,∞},{z,-∞,∞},Assumptions->0<b<a&&h>0]
])//Timing

i//TraditionalForm

Mean Radius

Cartesian

(1/(π a b h))Assuming[a>0&&b>0&&h>0,Integrate[(Sqrt[x^2+y^2+z^2])Boole[((x^2)/(a^2))+((y^2)/(b^2))<1],{x,-∞,∞},{y,-∞,∞},{z,-h/2,h/2}]]//Timing

...crashes in V9.0.0.2...

(1/(π a b h))Assuming[a>0&&b>0&&h>0,Integrate[(Sqrt[x^2+y^2+z^2])Boole[((x^2)/(a^2))+((y^2)/(b^2))<1],{x,-a,a},{y,-b,b},{z,-h/2,h/2}]]//Timing

...crashes in V9.0.0.2...

(1/(π a b h))Assuming[a>0&&b>0&&h>0,Integrate[(Sqrt[x^2+y^2+z^2])Boole[((x^2)/(a^2))+((y^2)/(b^2))<1],{z,-h/2,h/2},{x,-a,a},{y,-b,b}]]//Timing

Mean Square Radius

(1/(π a b h))Assuming[a>0&&b>0&&h>0,Integrate[(x^2+y^2+z^2)Boole[((x^2)/(a^2))+((y^2)/(b^2))<1],{x,-∞,∞},{y,-∞,∞},{z,-h/2,h/2}]]//Timing

With[{a=1,b=.123,h=.5},
{(1/12) (3 (a^2)+3 (b^2)+(h^2)),
(1/(π a b h))NIntegrate[(x^2+y^2+z^2)Boole[((x^2)/(a^2))+((y^2)/(b^2))<1],{z,-h/2,h/2},{y,-a,a},{x,-a,a}]
}]//Timing

Surface Area

Integrate[AreaElement[{a Cos[u],b Sin[u],v},{u,v}],{u,0,2π},{v,-h/2,h/2},Assumptions->a>0&&b>0]//Timing

FullSimplify[2 h (b EllipticE[1-((a^2)/(b^2))]+a EllipticE[1-((b^2)/(a^2))])-h 4 a EllipticE[1-((b^2)/(a^2))],0<b<a]

2 h (b EllipticE[1-((a^2)/(b^2))]-a EllipticE[1-((b^2)/(a^2))])/.{h->1,a->1,b->.5}

Volume

Integrate

Integrate[Boole[x^2/a^2+y^2/b^2<1&&-h/2<z<h/2],{x,-∞,∞},{y,-∞,∞},{z,-∞,∞},Assumptions->0<b<a&&h>0]//Timing

Integrate[Boole[x^2/a^2+y^2/b^2<1&&-h/2<z<h/2],{x,-∞,∞},{y,-∞,∞},{z,-∞,∞},Assumptions->a>0&&b>0&&h>0]//Timing

RegionMeasure

Assuming[assum,RegionMeasure[reg]]

Metric Properties

Metric Tensor

MetricTensor[{a Cos[u],b Sin[u],v},{u,v}]//FullSimplify

Christoffel Symbol of the Second Kind

FullSimplify[ChristoffelSymbols[{a Cos[u],b Sin[u],v},{u,v}],a>0&&b>0]

Vector Properties

eqn={a Cos[u],b Sin[u],v};
rules={Abs[x_]^(n_/;Mod[n,2]==0):>x^n};
assum=a>0&&0<u<2π&&v∈Reals;

Vector Length

Assuming[assum,FullSimplify[Norm[eqn]/.rules]]

Normal Vector

Assuming[assum,FullSimplify[NormalVector[eqn,{u,v}]/.rules]]