Ding-Dong Surface

Author

Eric W. Weisstein
June 20, 2013

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Surfaces/Ding-DongSurface.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/Ding-DongSurface.html.

©2013 Wolfram Research, Inc. except for portions noted otherwise

Initialization

surf[u_,v_]:=a{v(Sqrt[1-v])Cos[u],v(Sqrt[1-v])Sin[u],v}
dingdong=x^2+y^2-(1-z)z^2;

Cross-Section

Plot[(Sqrt[(1-z)])Abs[z],{z,-1,1.1},PlotStyle->Red]

Graphic

V5

<<Graphics`ContourPlot3D`

ContourPlot3D[dingdong,{x,-2,2},{y,-2,2},{z,-1,1},PlotPoints->{9,12},
ContourStyle->EdgeForm[],Boxed->False,
PlotRange->All]//Timing

V6

ContourPlot3D[dingdong==0,{x,-2,2},{y,-2,2},{z,-1,1},Boxed->False,PlotRange->All,Axes->False,Mesh->False,PlotPoints->20]

ParametricPlot3D[surf[u,v]/.a->1,{u,0,2π},{v,-1,1},PlotRange->All,Boxed->False,Axes->False]

Parametric

ParametricPlot3D[surf[u,v]/.a->1,{u,0,2π},{v,-1,1}]

Properties

Curvatures[surf[u,v],{u,v},FullSimplify[#,v<1&&a>0]&]

FullSimplify[PrincipalCurvatures[surf[u,v],{u,v}],(u|v)∈Reals&&a>0]

GaussianCurvature[dingdong,{x,y,z}]

Singular

SingularPoints[dingdong,{x,y,z}]

Surface Element

2π Integrate[(1/2) (Sqrt[(v^2) (8+v (-16+9 v))]),{v,0,1}]//FullSimplify

FullSimplify[TrigToExp[(1/243) π (21+48 (Sqrt[2])+32 ArcSinh[2 (Sqrt[2])]+16 Log[2])]]

N[(1/243) π (21+48 (Sqrt[2])+16 Log[2]+32 Log[3+2 (Sqrt[2])])]

Expand[(1+Sqrt[2])^2]

(1/243) π (21+48 (Sqrt[2])+16 Log[2]+64 Log[1+Sqrt[2]])//N

Volume

Numeric

NIntegrate[Boole[x^2+y^2-(1-z)z^2<0],{x,-∞,∞},{y,-∞,∞},{z,0,∞}]

Cartesian

Integrate[Boole[x^2+y^2-(1-z)z^2<0],{z,0,∞},{y,-∞,∞},{x,-∞,∞}]

Cylindrical

FullSimplify[x^2+y^2-(1-z)z^2/.{x->r Cos[θ],y->r Sin[θ]},r>0&&0<θ<2π]

Integrate[Boole[(r^2)+(-1+z) (z^2)<0]r,{z,0,∞},{θ,0,2π},{r,0,∞}]

Solid of Rotation

π Integrate[(1-z)z^2,{z,0,1}]

N[%]

Centroid

Cartesian

Integrate[{x,y,z}Boole[x^2+y^2-(1-z)z^2<0],{z,0,∞},{y,-∞,∞},{x,-∞,∞}]/(π/12)

Cylindrical

Integrate[{r Cos[θ],r Sin[θ], z}Boole[(r^2)+(-1+z) (z^2)<0]r,{z,0,∞},{θ,0,2π},{r,0,∞}]/(π/12)

Inertia Tensor

Cartesian

(M/(π/12))Integrate[InertiaTensor[{x,y,z}]Boole[x^2+y^2-(1-z)z^2<0],{x,-∞,∞},{y,-∞,∞},{z,0,∞}]

(M/(π/12))Integrate[InertiaTensor[{x,y,z}]Boole[x^2+y^2-(1-z)z^2<0],{z,0,∞},{y,-∞,∞},{x,-∞,∞}]

Cylindrical

(M/(π/12))Integrate[Boole[(r^2)+(-1+z) (z^2)<0]r InertiaTensor[{r,θ,z},"CoordinateSystem"->"Cylindrical"],{z,0,∞},{r,0,∞},{θ,0,2π}]

Metric Properties

Metric Tensor

MetricTensor[surf[u,v],{u,v}]//FullSimplify

Christoffel Symbol of the Second Kind

FullSimplify[ChristoffelSymbols[surf[u,v],{u,v}],a>0]

Vector Properties

eqn=a{v Sqrt[1-v]Cos[u],v Sqrt[1-v]Sin[u],v};

Vector Length

FullSimplify[FullSimplify[Norm[eqn],a>0&&(u|v)∈Reals]/.Abs[x_]^(n_/;Mod[n,2]==0):>x^n]

Normal Vector

Assuming[a>0&&(u|v)∈Reals,FullSimplify[NormalVector[eqn,{u,v}]/.Abs[x_]^(n_/;Mod[n,2]==0):>x^n]]