Modified Spherical Bessel Function of the First Kind

Author

Eric W. Weisstein
May 19, 2004

This notebook downloaded from http://mathworld.wolfram.com/notebooks/SpecialFunctions/ModifiedSphericalBesselFunctionoftheFirstKind.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/ModifiedSphericalBesselFunctionoftheFirstKind.html.

©2005 Wolfram Research, Inc. except for portions noted otherwise

Enumeration

FullSimplify[SphericalBesselI[#,x]&/@Range[0,4],x>0]//ColumnForm//TraditionalForm

{s,c}=Map[Reverse,Transpose[Map[CoefficientList[#,x]&,(Expand/@Coefficient[#,{Sinh[x],Cosh[x]}]&/@Numerator/@Simplify[SphericalBesselI[#,x]&/@Range[0,20],x>0]),{1}]],{2}];

Parity

FullSimplify[SphericalBesselI[#,x]/SphericalBesselI[#,-x]&/@Range[0,4],x>0]

Identities

FullSimplify[Table[Subtract@@{SphericalBesselI[n,x],(I^(-n))SphericalBesselJ[n,I x]},{n,0,4}],x>0]

FullSimplify[Subtract@@{SphericalBesselI[n,x],(I^(-n))SphericalBesselJ[n,I x]},n∈Integers&&x>0]

Recurrence

g[0,z_]:=1/z
g[1,z_]:=-1/z^2
g[n_?Positive,z_]:=g[n-2,z]-(2n-1)g[n-1,z]/z
g[n_?Negative,z_]:=g[n+2,z]+(2n+3)g[n+1,z]/z

Simplify[g[#,x]&/@Range[0,4]]

Reverse[CoefficientList[#,x]]&/@Expand[Numerator/@Simplify[g[#,x]&/@Range[0,10]]]

Take[s,11]

Simplify[g[#,x]&/@Range[-4,0]]

Reverse[CoefficientList[#,x]]&/@Expand[x Numerator/@Simplify[g[#,x]&/@Range[-1,-11,-1]]]

Take[c,11]

Plot

<<Graphics`Colors`

Plot[Evaluate[SphericalBesselI[#,x]&/@Range[0,6]],{x,.02,6},PlotStyle->{Black,Red,Yellow,Green,Blue,Purple,Violet},
AxesLabel->TraditionalForm/@{x,(Subscript[i, n])[x]}]