Inverse Trigonometric Functions

Author

Eric W. Weisstein
December 13, 2003

This notebook downloaded from http://mathworld.wolfram.com/notebooks/SpecialFunctions/InverseTrigonometricFunctions.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/InverseTrigonometricFunctions.html.

©2005 Wolfram Research, Inc. except for portions noted otherwise

Plots

<<Utilities`Plot`

Show[Block[{$DisplayFunction=Identity},
GraphicsArray[Partition[{
PlotDiscontinuous[ArcCsc[x],{x,{-10,-1},{1,10}},
PlotRange->{Automatic,{-1.7,1.7}},
AxesLabel->TraditionalForm/@{x,ArcCsc[x]},
HorizontalAsymptotes->{0},
VerticalAsymptotes->{-1,1},
PlotStyle->Red,
Epilog->{PointSize[.025],Red,Point/@{{1,Pi/2},{-1,-Pi/2}}},
Ticks->{Automatic,{#,TraditionalForm[#]}&/@Range[-Pi/2,Pi/2,Pi/4]}],
Plot[ArcCos[x],{x,-1,1},
PlotStyle->Red,
AxesLabel->TraditionalForm/@{x,ArcCos[x]},
Epilog->{Red,PointSize[.05],Point/@{{-1,Pi},{1,0}}},
Ticks->{Automatic,{#,TraditionalForm[#]}&/@Range[0,Pi,Pi/4]}],
PlotDiscontinuous[ArcCot[x],{x,-10,0,10},AxesLabel->TraditionalForm/@{x,ArcCot[x]},
PlotStyle->Red,
HorizontalAsymptotes->{0},
Epilog->{PointSize[.025],Red,Point[{0,ArcCot[0]}]},
Ticks->{Automatic,{#,TraditionalForm[#]}&/@Range[-Pi/2,Pi/2,Pi/4]}],
PlotDiscontinuous[ArcSec[x],{x,{-10,-1},{1,10}},
PlotRange->{Automatic,{0,Pi}},
AxesLabel->TraditionalForm/@{x,ArcSec[x]},
PlotStyle->Red,
VerticalAsymptotes->{-1,1},
HorizontalAsymptotes->{Pi/2},
Epilog->{Red,PointSize[.05],Point/@{{-1,Pi},{1,0}}},
Ticks->{Automatic,{#,TraditionalForm[#]}&/@Range[0,Pi,Pi/4]}],
Plot[ArcSin[x],{x,-1,1},AxesLabel->TraditionalForm/@{x,ArcSin[x]},
PlotRange->{Automatic,{-1.8,1.8}},
PlotStyle->Red,
Epilog->{Red,PointSize[.05],Point/@{{-1,-Pi/2},{1,Pi/2}}},
Ticks->{Automatic,{#,TraditionalForm[#]}&/@Range[-Pi/2,Pi/2,Pi/4]}],
PlotDiscontinuous[ArcTan[x],
{x,-10,10},
AxesLabel->TraditionalForm/@{x,ArcTan[x]},
HorizontalAsymptotes->{-1,1}Pi/2,
PlotStyle->Red,
PlotRange->{Automatic,{-1.8,1.8}},
Ticks->{Automatic,{#,TraditionalForm[#]}&/@Range[-Pi/2,Pi/2,Pi/4]}]
},3]]
],ImageSize->500]

Inverse-Forward Identities

FullSimplify[ArcTan[Cot[x]]-(Pi/2-x),0<x<Pi]

FullSimplify[ArcSin[Cos[x]]-(Pi/2-x),0<x<Pi]

FullSimplify[ArcSec[Csc[x]]-(Pi/2-x),0<x<Pi/2]

Plot[#-(Pi/2-x),{x,-Pi,4},PlotStyle->Red,PlotRange->All]&/@{ArcTan[Cot[x]],ArcSin[Cos[x]],ArcSec[Csc[x]]}

Forward-Inverse Identities

<<Utilities`Typesetting`

{#,ReleaseHold[#]}&/@{HoldForm[Cos[ArcSin[x]]],
HoldForm[Cos[ArcTan[x]]],
HoldForm[Sin[ArcCos[x]]],
HoldForm[Sin[ArcTan[x]]],
HoldForm[Tan[ArcCos[x]]],
HoldForm[Tan[ArcSin[x]]]}//TableForm//TraditionalForm

Inverse Sum Identities

<<Graphics`Colors`

{#,FullSimplify[#]}&/@{ArcSin[x]+ArcCos[x],ArcTan[x]+ArcCot[x],ArcSec[x]+ArcCsc[x]}//TableForm//TraditionalForm

FullSimplify[ArcCot[x]+ArcTan[x],x>0]

Plot[#,{x,-2Pi,2Pi},PlotStyle->Red]&/@{ArcSin[x]+ArcCos[x],ArcCot[x]+ArcTan[x],ArcSec[x]+ArcCsc[x]}

Complex Inverse Identities

TrigToExp[ArcSin[z]]

TrigToExp[ArcCos[z]]

FullSimplify[TrigToExp[ArcTan[z]]]