Hermite Polynomial

Author

Eric W. Weisstein
September 14, 2008

This notebook downloaded from http://mathworld.wolfram.com/notebooks/SpecialFunctions/HermitePolynomial.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/HermitePolynomial.html.

©2008 Wolfram Research, Inc. except for portions noted otherwise

Enumeration

poly=HermiteH;

poly[#,x]&/@Range[0,10]//ColumnForm//TraditionalForm

DeleteCases[CoefficientList[poly[#,x],x],0]&/@Range[0,10]

Flatten[%]

Plot

Plot[Evaluate[Table[HermiteH[n,x],{n,5}]],{x,-2,2},PlotStyle->{Red,Yellow,Green,Blue,Purple},PlotRange->50]

Definitions

Expand[Table[{n,
HermiteH[n,x],
Coefficient[Series[Exp[2x t-t^2],{t,0,n}]n!,t,n],
(-1)^n Exp[x^2]D[Exp[-x^2],{x,n}],
Exp[x^2/2]Nest[(x#-D[#,x])&,Exp[-x^2/2],n]
},{n,5}]]//TableForm

Table[(-1)^n Sqrt[π]/2 Exp[x^2]D[Erf[x],{x,n+1}]-HermiteH[n,x],{n,10}]//Simplify

EGF

GeneratingFunction[HermiteH[n,x],n,t]

TimeConstrained[FunctionExpand[%],60]//Timing

Sum[HermiteH[n,x]((t^n)/(n!)),{n,0,∞}]

SeriesCoefficient[(E^(-(t^2)+2 t x)),{t,0,n}]

Orthogonality

Integrate[Exp[-x^2]HermiteH[m,x]HermiteH[n,x],{x,-∞,∞}]

Integrate[Exp[-x^2]HermiteH[n,x]HermiteH[n,x],{x,-∞,∞}]

u[n_,x_]:=Sqrt[a/(Sqrt[π]n! 2^n)]HermiteH[n,a x]Exp[-a^2 x^2/2]

{PowerExpand@Table[Integrate[u[n,x]D[u[m,x],x],{x,-∞,∞},GenerateConditions->False],{m,5},{n,5}]//MatrixForm,Table[Which[
m==n+1,a Sqrt[(n+1)/2],
m==n-1,-a Sqrt[n/2],
True,0],
{m,5},{n,5}]//MatrixForm}

{PowerExpand@Table[Integrate[u[n,x]u[m,x],{x,-∞,∞},GenerateConditions->False],{m,5},{n,5}]//MatrixForm,Table[KroneckerDelta[m,n],
{m,5},{n,5}]//MatrixForm}

Discriminant

Product[k^k,{k,n}]

Table[Hyperfactorial[n],{n,6}]

Table[2^(3n(n-1)/2)Hyperfactorial[n],{n,6}]

Identities

(Subscript[H, n])(x)==(((2 x))^n) (Subscript[, 2])(Subscript[F, 0])(-(n/2),-(1/2) (n-1);;-(1/(x^2)))

FullSimplify[(2x)^n HypergeometricPFQ[{-n/2,-(n-1)/2},{},-1/x^2],n∈Integers&&n≥0]

Subtract@@@Table[{HermiteH[n,x],(2x)^n HypergeometricPFQ[{-n/2,-(n-1)/2},{},-1/x^2]}/.{n->Random[Integer,{0,50}],x->Random[Complex,5(I+1){-1,1},100]},{20}]//Chop//Union

(Subscript[H, n])(x)==(2^n) (x^n) ((((x^2)))^(-(n/2))) U(-(n/2),(1/2),(x^2))

Subtract@@@Table[{HermiteH[n,x],(2^n) (x^n) ((((x^2)))^(-n/2)) HypergeometricU[-(n/2),(1/2),x^2]}/.{n->Random[Integer,{0,50}],x->Random[Complex,5(I+1){-1,1},100]},{20}]//Chop//Union

Subtract@@@Table[{HermiteH[n,x],(2^n)  HypergeometricU[-(n/2),(1/2),x^2]}/.{n->Random[Integer,{0,50}],x->Random[Complex,5(I+1){0,1},100]},{20}]//Chop//Union

(Subscript[H, n])(-x)==(((-1))^n) (Subscript[H, n])(x)

FullSimplify[HermiteH[n,-x]-(-1)^n HermiteH[n,x],n∈Integers&&n≥0]

FunctionExpand[HermiteH[n,-x],n∈Integers&&n≥0]

Table[HermiteH[n,-x]-(-1)^n HermiteH[n,x],{n,0,10}]

v5.2

HermiteH[n,-x]

v6

HermiteH[n,-x]

V7

HermiteH[n,-x]

FunctionExpand[HermiteH[n,-x],n∈Integers&&n≥0]

Sum Identities

(∑_(k=0)^n)(({{n}, {k}})) (Subscript[H, k])(y) (Subscript[H, n-k])(x)==(2^(n/2)) (Subscript[H, n])((1/(Sqrt[2])) (x+y))

Expand[Table[Sum[Binomial[n,k]HermiteH[k,y]HermiteH[n-k,x],{k,0,n}]-2^(n/2)HermiteH[n,2^(-1/2)(x+y)],{n,0,10}]]

V7

Sum[Binomial[n,k]HermiteH[k,y]HermiteH[n-k,x],{k,0,n}]

(∑_(k=0)^n)(({{n}, {k}})) (Subscript[H, k])(x) (((2 y))^(n-k))-(Subscript[H, n])(x+y)

V7

Sum[Binomial[n,k]HermiteH[k,x](2y)^(n-k),{k,0,n}]

(∑_(k=0)^n)(((-1))^(n-k)) (({{n}, {k}})) (Subscript[H, n])(k)==(2^n) n!

V6

Sum[(((-1))^(n-k))Binomial[n,k]HermiteH[n,k],{k,0,n}]

Table[(2^n)n!,{n,0,5}]

Table[Sum[(((-1))^(n-k))Binomial[n,k]HermiteH[n,k],{k,0,n}],{n,0,5}]

V7

Sum[(((-1))^(n-k))Binomial[n,k]HermiteH[n,k],{k,0,n}]

(Subscript[H, n])(x+y)==(((H+2 y))^n)

Subtract@@@Expand[Table[{HermiteH[n,x+y],Expand[(H+2y)^n]},{n,0,10}]/.H^n_.:>HermiteH[n,x]]//Union

(Subscript[H, n])(x)==(Subscript[H, n])(0)+(∑_(m=0)^(⌊n/2⌋))(∑_(k=1)^(n-2 m))(((Subscript[𝒮, n-2 m]^((k))) (((-1))^k) (Subscript[(-x), k]) ((((-1))^m) (2^(n-2 m)) n!))/((n-2 m)! m!))

V6

Subtract@@@Table[{HermiteH[n,x],HermiteH[n,0]+Sum[StirlingS2[n-2m,k](((-1))^k) Pochhammer[-x,k](((((-1))^m)(2^(n-2m))n!)/((n-2m)!m!)),{m,0,Floor[n/2]},{k,n-2m}]},{n,10}]//Expand//Union

V7

HermiteH[n,0]+Sum[StirlingS2[n-2m,k](((-1))^k) Pochhammer[-x,k](((((-1))^m)(2^(n-2m))n!)/((n-2m)!m!)),{m,0,Floor[n/2]},{k,n-2m}]

(Subscript[H, 2 k])(x)==(((-2))^k) (2 k-1)!! (Subscript[, 1])(Subscript[F, 1])(-k;(1/2);(x^2))

(((-1))^k)(2^k)(2k-1)!!(1+Sum[((Product[-4k+4l,{l,0,j-1}])/((2j)!))(x^(2j)),{j,k}])

FullSimplify[(((-2))^k) (-1+2 k)!! Hypergeometric1F1[-k,(1/2),(x^2)],k∈Integers&&k>0]

Table[(((-2))^k) (-1+2 k)!! Hypergeometric1F1[-k,(1/2),(x^2)]-HermiteH[2k,x],{k,0,5}]//Expand

FullSimplify[(((-2))^k) (-1+2 k)!! Hypergeometric1F1[-k,(1/2),(x^2)]-HermiteH[2k,x],k∈Integers&&k>0]

FunctionExpand[(((-2))^k) (-1+2 k)!! Hypergeometric1F1[-k,(1/2),(x^2)],k∈Integers&&k>0]

(Subscript[H, 2 k+1])(x)==(((-1))^k) (2^(k+1)) x (2 k+1)!! (Subscript[, 1])(Subscript[F, 1])(-k;(3/2);(x^2))

(((-1))^k)(2^(k+1))(2k+1)!!(x+Sum[((Product[-4k+4l,{l,0,j-1}])/((2j+1)!))(x^(2j+1)),{j,k}])

FullSimplify[(((-1))^k) (2^(1+k)) (1+2 k)!! (x+x (-1+Hypergeometric1F1[-k,(3/2),(x^2)])),k∈Integers&&k>0]

Table[(((-1))^k) (2^(1+k)) x (1+2 k)!! Hypergeometric1F1[-k,(3/2),(x^2)]-HermiteH[2k+1,x],{k,0,5}]//Expand

FullSimplify[(((-1))^k) (2^(1+k)) x (1+2 k)!! Hypergeometric1F1[-k,(3/2),(x^2)]-HermiteH[2k+1,x],k∈Integers&&k>0]

FunctionExpand[(((-2))^k) (-1+2 k)!! Hypergeometric1F1[-k,(1/2),(x^2)],k∈Integers&&k>0]

Recurrence Relation

RSolve[{H[n+1,x]==2x H[n,x]-2n H[n-1,x],H[0,x]==1,H[1,x]==2x},H[n,x],n]

D[HermiteH[n,x],x]

Generalized

EGF==exp(m t x-(t^m))

SeriesCoefficient[Exp[m x t-(t^m)],{t,0,n}]

Series[Exp[m x t-(t^m)],{t,0,2}]

Series[Exp[m x t-t],{t,0,2}]

(Subscript[He, n])(x)

Expand[Table[{n,2^(-n/2)HermiteH[n,x/Sqrt[2]]},{n,5}]]//TableForm//TraditionalForm

DeleteCases[CoefficientList[2^(-#/2)HermiteH[#,x/Sqrt[2]],x],0]&/@Range[0,10]

Flatten[%]