Dilogarithm

Author

Eric W. Weisstein
January 18, 2022

This notebook downloaded from http://mathworld.wolfram.com/notebooks/SpecialFunctions/Dilogarithm.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/Dilogarithm.html.

©2022 Wolfram Research, Inc. except for portions noted otherwise

Initialization

RogersL[x_]:=PolyLog[2,x]+Log[x]Log[1-x]/2
RogersL[1]:=Pi^2/6

Plots

Real Axis

Plot[PolyLog[2,x],{x,-5,1},
PlotStyle->Red,
AxesLabel->TraditionalForm/@{x,PolyLog[2,x]},LabelStyle->Directive[Black,FontFamily->"Times"]]

Complex Plane

ComplexPlot3D[PolyLog[2,z],{z,-5,5}]//Timing

ComplexContourPlot[PolyLog[2,z],{z,-5,5}]//Timing

Abel's functional equation

L(1-x)+L(x)==1

FullSimplify[L[x]+L[1-x]]

Limit[L[x],x->1]

L(x)+L(y)==L(x y)+L((((1-x) y)/(1-x y)))+L(((x (1-y))/(1-x y)))

FullSimplify[{L[x]+L[y],L[x y]+L[x(1-y)/(1-x y)]+L[y(1-x)/(1-x y)]}]

Table[Subtract@@%/. {x->Random[],y->Random[]},{20}]//Chop

FullSimplify[L[x]+L[y]-L[x y]-L[x(1-y)/(1-x y)]-L[y(1-x)/(1-x y)]]

Table[% /. {x->Random[],y->Random[]},{20}]//Chop

Abel's duplication formula

L(x)-L((x/(x+1)))==((L((x^2)))/2)

FullSimplify[L[x]-L[x/(1+x)]-L[x^2]/2]

Table[%80 /. x->Random[],{20}]//Chop

Identities for rational arguments

(PolyLog[2, -(1/2)])+((PolyLog[2, (1/9)])/6)==-((π^2)/18)-(1/2) (log^2)(2)-(((log^2)(3))/3)+log(3) log(2)

id={PolyLog[2,-1/2]+1/6PolyLog[2,1/9],(-1/18Pi^2+Log[2]Log[3]-Log[2]^2/2-1/3 Log[3]^2)};

FullSimplify[Subtract@@id]

N[Subtract@@id,20]

(PolyLog[2, -(1/3)])-((PolyLog[2, (1/9)])/3)==(((log^2)(3))/6)-((π^2)/18)

id={PolyLog[2,-1/3]-1/3PolyLog[2,1/9],-1/18 Pi^2+1/6 Log[3]^2};

FullSimplify[Subtract@@id]

N[Subtract@@id,20]

(PolyLog[2, (1/3)])-((PolyLog[2, (1/9)])/6)==((π^2)/18)-(((log^2)(3))/6)

Ramanujan

Campbell 2021

id={(PolyLog[2,1/3]-1/6PolyLog[2,1/9]),(1/18 Pi^2-1/6 Log[3]^2)};

FullSimplify[Subtract@@id]

N[Subtract@@id,20]

(PolyLog[2, (1/4)])+((PolyLog[2, (1/9)])/3)==((π^2)/18)-2 (log^2)(2)-((2 (log^2)(3))/3)+2 log(3) log(2)

id={PolyLog[2,1/4]+1/3PolyLog[2,1/9],(1/18 Pi^2+2Log[2]Log[3]-2Log[2]^2-2/3Log[3]^2)};

FullSimplify[Subtract@@id]

N[Subtract@@id,20]

(PolyLog[2, -(1/8)])+(PolyLog[2, (1/9)])==-(1/2) (log^2)((9/8))

id={PolyLog[2,-1/8]+PolyLog[2,1/9],(-1/2 Log[9/8]^2)};

FullSimplify[Subtract@@id]

N[Subtract@@id,20]

36 (PolyLog[2, (1/2)])-36 (PolyLog[2, (1/4)])-12 (PolyLog[2, (1/8)])+6 (PolyLog[2, (1/64)])==(π^2)

id={36PolyLog[2,1/2]-36PolyLog[2,1/4]-12PolyLog[2,1/8]+6PolyLog[2,1/64],Pi^2};

FullSimplify[Subtract@@id]

N[Subtract@@id,20]

12 (PolyLog[2, (1/2)])==(π^2)-6 (log^2)(2)

id={Pi^2-6Log[2]^2,12PolyLog[2,1/2]};

FullSimplify[Subtract@@id]

N[Subtract@@id,20]

Two-term identities for irrational arguments

(PolyLog[2, (Sqrt[2])-1])-(PolyLog[2, 1-(Sqrt[2])])==((π^2)/8)-(1/2) (log^2)((Sqrt[2])+1)

Lima 2012, Campbell 2021

N[{PolyLog[2,(Sqrt[2])-1]-PolyLog[2,1-(Sqrt[2])],((π^2)/8)-(1/2)((Log[1+(Sqrt[2])])^2)},20]

FullSimplify[Subtract@@{PolyLog[2,(Sqrt[2])-1]-PolyLog[2,1-(Sqrt[2])],((π^2)/8)-(1/2)((Log[1+(Sqrt[2])])^2)}]//Timing

(PolyLog[2, (1/(ϕ^3))])-(PolyLog[2, -(1/(ϕ^3))])==(((ϕ^3) ((π^2)-18 (log^2)(ϕ)))/(3 ((ϕ^6)-1)))

N[{PolyLog[2,(GoldenRatio^(-3))]-PolyLog[2,-(GoldenRatio^(-3))],(((GoldenRatio^3)((π^2)-18((Log[GoldenRatio])^2)))/(3((GoldenRatio^6)-1)))},20]

FullSimplify[Subtract@@{PolyLog[2,(GoldenRatio^(-3))]-PolyLog[2,-(GoldenRatio^(-3))],(((GoldenRatio^3)((π^2)-18((Log[GoldenRatio])^2)))/(3((GoldenRatio^6)-1)))}]//Timing

(PolyLog[2, i (2-(Sqrt[3]))])-(PolyLog[2, -i (2-(Sqrt[3]))])==((2 i (Sqrt[7-4 (Sqrt[3])]) (8 C-π log((Sqrt[3])+2)))/(3 (8-4 (Sqrt[3]))))

N[{PolyLog[2,I(2-(Sqrt[3]))]-PolyLog[2,-I(2-(Sqrt[3]))],((2I Sqrt[7-4(Sqrt[3])](8Catalan-π Log[2+(Sqrt[3])]))/(3(8-4(Sqrt[3]))))},20]

FullSimplify[Subtract@@{

FullSimplify[Subtract@@{PolyLog[2,I(2-(Sqrt[3]))]-PolyLog[2,-I(2-(Sqrt[3]))],((2I Sqrt[7-4(Sqrt[3])](8Catalan-π Log[2+(Sqrt[3])]))/(3(8-4(Sqrt[3]))))}]//Timing

(PolyLog[2, (i/(Sqrt[3]))])-(PolyLog[2, -(i/(Sqrt[3]))])==((i (-16 (π^2)-6 (Sqrt[3]) π log(3)+15 (PolyGamma2[1, (1/3)])+3 (PolyGamma2[1, (1/6)])))/(36 (Sqrt[3])))

N[{PolyLog[2,(I/(Sqrt[3]))]-PolyLog[2,-(I/(Sqrt[3]))],((I(3PolyGamma[1,(1/6)]+15PolyGamma[1,(1/3)]-6(Sqrt[3])π Log[3]-16(π^2)))/(36(Sqrt[3])))},20]

FullSimplify[Subtract@@{PolyLog[2,(I/(Sqrt[3]))]-PolyLog[2,-(I/(Sqrt[3]))],((I(3PolyGamma[1,(1/6)]+15PolyGamma[1,(1/3)]-6(Sqrt[3])π Log[3]-16(π^2)))/(36(Sqrt[3])))}]//Timing

Identities for golden ratio arguments

Off[$MaxExtraPrecision::"meprec"];
ids={{PolyLog[2,(-1/2*(Sqrt[5]+1))]==-1/10*Pi^2-(Log[1/2*(Sqrt[5]+1)])^2},{PolyLog[2,(-1/2*(Sqrt[5]-1))]==-1/15*Pi^2+1/2*(Log[1/2*(Sqrt[5]+1)])^2},{PolyLog[2,(1/2*(3-Sqrt[5]))]==1/15*Pi^2-(Log[1/2*(Sqrt[5]+1)])^2},{PolyLog[2,(1/2*(Sqrt[5]-1))]==1/10*Pi^2-(Log[1/2*(Sqrt[5]+1)])^2}};
TableForm[ids]

RootReduce[1/GoldenRatio]

RootReduce[1/GoldenRatio^2]

FunctionExpand[#[[1,2]]&/@ids]//TableForm

N[ids]

{Limit[L[x],x->0],Limit[L[x],x->1]}

ρ=(Sqrt[5]-1)/2;

{FullSimplify[L[#]],N[L[#]]}&/@{0,1-ρ,1/2,ρ,1}

Identities for complex arguments

Im((PolyLog[2, i ((Sqrt[2])-1)]))==(1/16) (π log(3-2 (Sqrt[2]))+((-4 (π^2)+(PolyGamma2[1, (1/8)])+(PolyGamma2[1, (3/8)]))/(2 (Sqrt[2]))))

From W. Gosper on math-fun, Sep. 19, 2021

id={Im[PolyLog[2,I (√2-1)]],(π Log[3-2√2]+(PolyGamma[1,1/8]+PolyGamma[1,3/8]-4π^2)/(2 √2))/16}

FullSimplify[Subtract@@id]

N[Subtract@@id,20]

Bailey and Borwein Identity

(Subscript[α, 1])=Root[x^10+x^9-x^7-x^6-x^5-x^4-x^3+x+1,2];

N[(Subscript[α, 1]),20]

l={{1,-630},{-2,-315},{-3,-210},{-10,-126},{-7,-90},{18,-35},{84,-15},{90,-14},{-4,-9},{339,-8},{45,-7},{265,-6},{-273,-5},{-678,-4},{-1016,-3},{-744,-2},{-804,-1}};

(id=Plus@@(#1PolyLog[2,α^#2]&@@@l)-22050Log[α]^2+2003Zeta[2])//TraditionalForm

Block[{α=Root[x^10+x^9-x^7-x^6-x^5-x^4-x^3+x+1,2]},
N[id,600]
]//Timing

Dilogarithm functional equations

λ=2Cos[Pi/7];
ρ=(Sqrt[5]-1)/2;
δ=(Sqrt[3+2Sqrt[5]]-1)/2;

{FullSimplify[#],N[#],N[4/7]}&/@{L[1/λ^2]+L[1/(λ^2-1)^2]}

{FullSimplify[#],N[#],N[5/7]}&/@{L[1/λ^2]+L[1/(λ+1)]}

{FullSimplify[#],N[#],N[13/10]}&/@{L[Sqrt[ρ]]+L[1/(Sqrt[ρ]+1)]}

{FullSimplify[#],N[#],N[3/5]}&/@{L[1-δ^2]+L[1/(δ+1)^2]}

L-Algebraic

FullSimplify[LR[1/64]-2LR[1/8]-6LR[1/4]+2LR[1]]

N[%]

Loxton Identities

Loxton[ρ_,e_List,c_]:=Module[{k},
(Table[L[ρ^k]/k,{k,Length[e]}]).e-c
]

Loxton[1,{1},1]

Loxton[1/2,{1},1/2]

FullSimplify[Loxton[1/2(Sqrt[5]-1),{1},3/5]]

N[%]

loxton={
{1,{1},1},
{1/2,{1},1/2},
{1/2,{-1,6,3,0,0,-3},1/2}, (*EWW*)
{1/3,{3,-1},1},
{(Sqrt[5]-1)/2,{1,-1,-12,0,0,6,0,0},-3/5}, (*EWW*)
{(Sqrt[5]-1)/2,{1},6/10},
{Sqrt[(3-Sqrt[5])/2],{1},6/10}, (*1/15*)
{(Sqrt[5]-2)^(1/3),{2,-1},1},(*1/12*)
(*{(((7+4Sqrt[5])/2)^(1/4)),{7,-6,4,0,0,-3},7/36} ((7-4Sqrt[5])/2)^(1/4)*)
{Sqrt[2]-1,{2,-1},6/8},
{Sqrt[2]-1,{1,2,0,-1},5/8},
{3-2Sqrt[2],{5,-2},1},
{(Sqrt[3]-1)/2,{2,1,-1},5/6},
{Sqrt[3]-1,{2,-3,-1,0,0,1},1/2},
{2-Sqrt[3],{4,1,0,-1},5/4},
{2-Sqrt[3],{5,-3,-1,0,0,1},12/9},
{5-2Sqrt[6],{23,-15,-3,0,0,3},3},
{(Sqrt[13]-3)/2,{4,-2,-2,0,0,1},7/6},
{(Sqrt[13]-1)/6,{3,1,-3,0,0,1},12/9},
{(Sqrt[13]+1)/6,{3,-4,-3,0,0,2},6/9},
{4-Sqrt[15],{15,2,-3,-2},5/2},
{(5-Sqrt[21])/2,{7,-1,-3,0,0,1},5/3},
{Sec[2Pi/7]/2,{1,-2},1/7},
{Sec[Pi/7]/2,{1,1},5/7},
{2Cos[3Pi/7],{1,1},12/21},
{Sec[Pi/9]/2,{1,2,-1},7/9},
{Sec[2Pi/9]/2,{1,-3,-1,0,0,1},-1/9},
{2Cos[4Pi/9],{1,-3,-1,0,0,1},1/9},
{Root[-1+2 #1+((#1)^3)&,1],{1,5,0,-4},1},
{Root[-1+2 #1+((#1)^3)&,1],{3,1,12,0,0,-6},2},
{Root[-1+#1+2 ((#1)^3)&,1],{2,1,3,-2},6/4},
{Root[-1+#1+((#1)^3)&,1],{2,6,3,0,0,-3},3},
{Root[-1+4 #1-3 ((#1)^2)+((#1)^3)&,1],{5,-9,-6,0,0,6},1},
{Root[-1+2 #1-((#1)^2)+((#1)^3)&,1],{1,6,6,0,0,-6},2},
{Root[-1+#1+((#1)^2)+((#1)^3)&,1],{1,1,-3},1/2},
{Root[-1+#1+((#1)^2)+((#1)^3)&,1],{2,3,0,-2},6/4} 
};

Loxton@@@loxton//N//Chop

Select[Loxton@@@loxton//N//Chop,#≠0&]

TeXForm/@loxton

Lattice Reduce Identities

LIdentities[{x_,c_},n_:8]:=Select[LatticeReduce[Rationalize[N[Transpose[Join[IdentityMatrix[n+1],
{10^15Append[Table[L[x^i]/i,{i,n}],-c]}]],30],10^-30]]//N,Abs[#[[-2]]]>.01&&Abs[#[[-1]]]<.1&]

LoxtonCheck[{x_,c_},l_List]:=Loxton[x,Drop[l,-2],c]

LIdentities[{1,1/6},8]

LIdentities[{1/2,1/6},8]

LIdentities[{1/2,1/2},8]

LIdentities[{1/2,1/24},8]

LIdentities[{1/3,1},8]

LIdentities[{1/3,1/32},8]

LIdentities[{(Sqrt[5]-1)/2,1/5}]

LIdentities[{(Sqrt[5]-1)/2,2/5}]

LIdentities[{(Sqrt[5]-1)/2,3/5}]

LoxtonCheck[{(Sqrt[5]-1)/2,-3/5},%[[-1]]]

Round[{1.`,-1.`,-12.`,0.`,0.`,6.`,0.`,0.`}]

LIdentities[{Sec[2Pi/7]/2,6/42}]

LIdentities[{Root[-1+#1+((#1)^2)+((#1)^3)&,1],1/3}]

LIdentities[{Root[-1+#1+((#1)^2)+((#1)^3)&,1],1/2}]

LIdentities[{Root[-1+#1+((#1)^2)+((#1)^3)&,1],3/2}]

Wrong 1

(((7-4Sqrt[5])/2)^(1/4))//N

(((7+4Sqrt[5])/2)^(1/4)-1)//N

L[x_]:=6/Pi^2(PolyLog[2,x]+Log[x]Log[1-x]/2)

7L[x]-6/2L[x^2]+4/3L[x^3]-3/6L[x^6]-7/36 6/Pi^2==0

((7-4Sqrt[5])/2)^(1/4)//N

r=x/.FindRoot[7L[x]-6/2L[x^2]+4/3L[x^3]-3/6L[x^6]==7/36 6/Pi^2,{x,.2,.6},WorkingPrecision->20]

Recognize[r,16,x,1]

Rogers L-Function Plot

Plot[{L[x],LR[x]},{x,0,1},PlotStyle->{Automatic,Red}]

Spence's function

Integrate[Log[1+t]/t,{t,0,x}]

Sum identity

Sum[L[1/k],{k,2,Infinity}]

DiscretePlot[((6 ((1/2) Log[1-(1/k)] Log[(1/k)]+PolyLog[2,(1/k)]))/(π^2)),{k,100}]

NSum[L[1/k],{k,2,Infinity},WorkingPrecision->20]

Sum[L[1/k^2],{k,2,Infinity}]

NSum[L[1/k^2],{k,2,Infinity},WorkingPrecision->20]

NSum[L[1/k^3],{k,2,Infinity},WorkingPrecision->20]

NSum[L[1/k^4],{k,2,Infinity},WorkingPrecision->20]