Spherical Segment

Author

Eric W. Weisstein
December 27, 2008

This notebook downloaded from http://mathworld.wolfram.com/notebooks/SolidGeometry/SphericalSegment.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/SphericalSegment.html.

©2008 Wolfram Research, Inc. except for portions noted otherwise

Relationships

FullSimplify[Solve[{
hb^2==R^2-b^2,
ha^2==R^2-a^2,
h==hb-ha},
R,{ha,hb}],h>0&&0<b<a]

Factor[(((((Sqrt[(a^4)-2 (a^2) (b-h) (b+h)+((((b^2)+(h^2)))^2)])/(2 h))))^2)]

Solve[{a^2==R^2-d^2,b^2==R^2-(d+h)^2},{d,R}]

Properties

Volume

Method of Washers

π Integrate[((R^2)-(y^2)),{y,d,d+h}]//Simplify

Boole

v5.2

Integrate[Boole[(x^2)+(y^2)+(z^2)<(R^2)],{x,-R,R},{y,-R,R},{z,d,d+h},Assumptions->d>0&&h>0&&R>0]

Integrate[Boole[(x^2)+(y^2)+(z^2)<(R^2)],{z,d,d+h},{x,-R,R},{y,-R,R},Assumptions->d>0&&h>0&&R>0]

Refine[Integrate[Boole[(x^2)+(y^2)+(z^2)<(R^2)],{z,d,d+h},Assumptions->d>0&&h>0],d>0&&h>0&&R>0]

Integrate[%,{x,-R,R},Assumptions->R>0]

V6.0.2

(v=Simplify[Integrate[Boole[(x^2)+(y^2)+(z^2)<(R^2)],{z,d,d+h},{x,-R,R},{y,-R,R},Assumptions->d>0&&h>0&&R>0],d>0&&h>0&&R>0])//Timing

(v=Simplify[Integrate[Boole[(x^2)+(y^2)+(z^2)<(R^2)],{x,-R,R},{y,-R,R},{z,d,d+h},Assumptions->d>0&&h>0&&R>0],d>0&&h>0&&R>0])//Timing

V7

v=Integrate[Boole[(x^2)+(y^2)+(z^2)<(R^2)],{z,d,d+h},{x,-R,R},{y,-R,R},Assumptions->d>0&&h>0&&R>0&&d+h<R]//Simplify

Integrate[Boole[(x^2)+(y^2)+(z^2)<(R^2)],{z,d,d+h},{x,-R,R},{y,-R,R},Assumptions->d>0&&h>0&&R>0&&d+h<R]//Simplify//Timing

Assuming[d>0&&h>0&&d+h<a&&a>0,Volume[(x^2)+(y^2)+(z^2)<(a^2)&&d<z<d+h,{x,y,z}]]//Timing

V8

Assuming[d>0&&h>0&&d+h<a&&a>0,Volume[(x^2)+(y^2)+(z^2)<(a^2)&&d<z<d+h,{x,y,z}]]//Timing

...hangs...

Numerical Check

Simplify[π h((R^2)-(d^2)-h d-(1/3)(h^2)),d>0&&h>0&&R>0]

With[{R=1,d=.2,h=.5},
{
NIntegrate[Boole[(x^2)+(y^2)+(z^2)<(R^2)],{x,-∞,∞},{y,-∞,∞},{z,d,d+h}],
π h((R^2)-(d^2)-h d-(1/3)(h^2)),
(1/6)π h(3(a^2)+3(b^2)+(h^2))/.{a->(Sqrt[(R^2)-(d^2)]),b->(Sqrt[(R^2)-(((d+h))^2)])}
}
]

Centroid

(zz=Integrate[z Boole[(x^2)+(y^2)+(z^2)<(R^2)],{z,d,d+h},{x,-R,R},{y,-R,R},Assumptions->d>0&&h>0&&R>0&&d+h<R])

(zz/v)//FullSimplify

V8

(1/(-(1/3) h π (3 (d^2)+3 d h+(h^2)-3 (R^2))))Integrate[{x,y,z} Boole[(x^2)+(y^2)+(z^2)<(a^2)],{z,d,d+h},{x,-a,a},{y,-a,a},Assumptions->d>0&&h>0&&a>0&&d+h<a]//Timing

Assuming[d>0&&h>0&&d+h<a&&a>0,Centroid[(x^2)+(y^2)+(z^2)<(a^2)&&d<z<d+h,{x,y,z}]]//Timing

...hangs...

InertiaTensor

InertiaTensor[{x,y,z}]

(M/(-(1/3) h π (3 (d^2)+3 d h+(h^2)-3 (R^2))))Integrate[InertiaTensor[{x,y,z}] Boole[(x^2)+(y^2)+(z^2)<(a^2)],{z,d,d+h},{x,-a,a},{y,-a,a},Assumptions->d>0&&h>0&&a>0&&d+h<a]//Timing

FullSimplify[%]

With[{ρ=(M/v)},ρ Integrate[Boole[(x^2)+(y^2)+(z^2)<(R^2)]InertiaTensor[{x,y,z}],{z,d,d+h},{x,-R,R},{y,-R,R},Assumptions->d>0&&h>0&&R>0&&d+h<R]]//FullSimplify

Factor[%]