Salinon

Author

Eric W. Weisstein
July 31, 2014

This notebook downloaded from http://mathworld.wolfram.com/notebooks/PlaneGeometry/Salinon.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/Salinon.html.

©2014 Wolfram Research, Inc. except for portions noted otherwise

Definitions

ineq=(x^2+y^2≤R^2&&y≥0&&(x-(R+r)/2)^2+y^2≥((R-r)/2)^2&&(x+(R+r)/2)^2+y^2≥((R-r)/2)^2)||(x^2+y^2≤r^2);

implreg=ImplicitRegion[ineq,{x,y}];

reg=RegionUnion[RegionDifference[Disk[{0,0},R,{0,π}],RegionUnion[Disk[{-(r+R)/2,0},(R-r)/2],Disk[{(r+R)/2,0},(R-r)/2]]],Disk[{0,0},r,{π,2π}]];

assum=0<r<R;

Plots

Diagram

LaminaData["Salinon","Diagram"]

DiscretizeRegion

Block[{R=1,r=.3},Show[DiscretizeRegion[reg],ImageSize->Small]]

Block[{R=1,r=.3},Show[DiscretizeRegion[implreg],ImageSize->Small]]

Schematic

Salignon[R_,r_]:={
Circle[{0,0},R,{0,Pi}],
Circle[{0,0},r,{-Pi,0}],
Circle[{#(R+r)/2,0},(R-r)/2,{0,Pi}]&/@{-1,1},
{Red,Circle[{0,(R-r)/2},(R+r)/2]}
}

Show[Graphics[Salignon[2,.5],AspectRatio->Automatic]]

InequalityGraphics

<<Graphics`InequalityGraphics`

With[{R=2,r=.5},
InequalityPlot[(x^2+y^2<R^2&&y>0&&(x-(R+r)/2)^2+y^2>((R-r)/2)^2&&(x+(R+r)/2)^2+y^2>((R-r)/2)^2)||(x^2+y^2<r^2),
{x},{y},Ticks->None,Epilog->{Red,Circle[{0,(R-r)/2},(R+r)/2]}]
]

RegionPlot

With[{R=2,r=.5},
RegionPlot[(x^2+y^2<R^2&&y>0&&(x-(R+r)/2)^2+y^2>((R-r)/2)^2&&(x+(R+r)/2)^2+y^2>((R-r)/2)^2)||(x^2+y^2<r^2),
{x,-R,R},{y,-r,R},Ticks->None,Epilog->{Red,Circle[{0,(R-r)/2},(R+r)/2]},AspectRatio->Automatic,MaxRecursion->8,Axes->True,Frame->False]
]

Properties

Area

Area

Assuming[assum,FullSimplify@Area[reg]]//Timing

Assuming[assum,FullSimplify@Area[implreg]]//Timing

Integrate

Simplify[π((1/2)R^2-((R-r)/2)^2+(1/2)r^2)]

area=Integrate[Boole[ineq],{x,-∞,∞},{y,-∞,∞},Assumptions->0<r<R]//FullSimplify

RegionMeasure

Assuming[assum,FullSimplify@RegionMeasure[reg]]//Timing

Assuming[assum,FullSimplify@RegionMeasure[implreg]]//Timing

AreaInertiaTensor

Integrate[AreaInertiaTensor[{x,y}]Boole[ineq],{x,-∞,∞},{y,-∞,∞},Assumptions->0<r<R]//FullSimplify

Centroid

Integrate

(1/area)Integrate[{x,y}Boole[ineq],{x,-∞,∞},{y,-∞,∞},Assumptions->0<r<R]//FullSimplify

RegionCentroid

Assuming[assum,FullSimplify@RegionCentroid[reg]]//Timing

Assuming[assum,FullSimplify@RegionCentroid[implreg]]//Timing

Convex

TimeConstrained[Region`ConvexRegionQ[reg],600]//Timing

TimeConstrained[Region`ConvexRegionQ[implreg],600]//Timing

GeneralizedDiameter

ineq[x_,y_]:=(x^2+y^2<=R^2&&y>=0&&(x-(R+r)/2)^2+y^2>=((R-r)/2)^2&&(x+(R+r)/2)^2+y^2>=((R-r)/2)^2)||(x^2+y^2<=r^2)

ineqs=FullSimplify[And@@ineq@@@{{x1,y1},{x2,y2}},0<r<R]

Maximize[{(x1-x2)^2+(y1-y2)^2,ineqs&&0<r<R},{x1,x2,y1,y2},Reals]//Timing

...ran overnight...

Perimeter

Simplify[π(R+r+r+(R-2r))]

RadiiOfGyration

Assuming[0<r<R,FullSimplify[RadiiOfGyration[ineq[x,y],{x,y}]]]