Chord

Author

Eric W. Weisstein
March 8, 2009

This notebook downloaded from http://mathworld.wolfram.com/notebooks/PlaneGeometry/Chord.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/Chord.html.

©2009 Wolfram Research, Inc. except for portions noted otherwise

Area

aa=PowerExpand[2Integrate[Sqrt[R^2-y^2]-r,{y,0,Sqrt[R^2-r^2]}]]

Limit[aa,r->R]

Limit[aa,r->0]

Variables

Solve[{r+s==R,Cos[θ/2]==r/R,c==2(Sqrt[(R^2)-(r^2)])}/.{r->.8,R->1},{θ,c,s}]

Diagram

ChordDiagram[r_,R_:1]:=Module[{q=ArcCos[r/R],x,y},
{x,y}=R Through[{Sin,Cos}[q]];
Graphics[{
Circle[{0,0},R],PointSize[.02],Point[{0,0}],
{Dashing[{.02,.02}],Opacity[.4],Line[{{-x,y},{0,0},{x,y}}]},
Red,Line[{{-x,y},{x,y}}],
Blue,Line[{{0,0},{0,y}}],
Green,Line[{{0,y},{0,R}}],
Black,{Opacity[.4],Circle[{0,0},.2,{π/2-q,π/2}]},Text[Row[{" ",θ/2," "}],.2R Through[{Sin,Cos}[q/2]],Background->White],
Text["r",{-.07R,y/2},Background->White],
Text["s",{-.07R,(y+R)/2},Background->White],
Text["R",.5{x,y}-{0,.14r},Background->White]
},BaseStyle->12]
]

ChordDiagram[.8]