Rose Curve

Author

Eric W. Weisstein
August 24, 2021

This notebook downloaded from http://mathworld.wolfram.com/notebooks/PlaneCurves/RoseCurve.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/RoseCurve.html.

©2021 Wolfram Research, Inc. except for portions noted otherwise

Plots

Integer Sin

GraphicsRow[Table[PolarPlot[Sin[n t],{t,0,(Mod[n+1,2]+1)Pi},
PlotLabel->TraditionalForm[HoldForm[n]==n],
Ticks->None,PlotStyle->Red,
LabelStyle->Directive[Black,12,FontFamily->"Times"]],{n,5}]]

Integer Cos

GraphicsRow[Table[PolarPlot[Cos[n t],{t,0,(Mod[n+1,2]+1)Pi},
PlotLabel->TraditionalForm[HoldForm[n]==n],
Ticks->None,PlotStyle->Red,
LabelStyle->Directive[Black,12,FontFamily->"Times"]],{n,5}]]

Rational

Pi Denominator[#]If[EvenQ[#/.Rational[x_,y_]:>x y],2,1]&/@{1/2,1/3,2/3,1/4,3/4,1/5,2/5,3/5}

GraphicsGrid[Partition[
PolarPlot[Sin[# t],{t,0,Pi Denominator[#]If[EvenQ[#/.Rational[x_,y_]:>x y],2,1]},
PlotLabel->TraditionalForm[n==InputForm[#]],
LabelStyle->Directive[Black,12,FontFamily->"Times"],
Ticks->None,PlotStyle->Red]&/@{1/2,1/3,2/3,1/4,3/4,1/5,2/5,3/5},UpTo[4]]]

Irrational

GraphicsRow[PolarPlot[Sin[# t],{t,0,30Pi},
PlotLabel->TraditionalForm[n==#],
Ticks->None,PlotStyle->Red,LabelStyle->Directive[Black,12,FontFamily->"Times"]]&/@{E,Pi,Sqrt[2]}]

Properties

ClosingAngle[n_]:=Denominator[n] (2-Mod[Numerator[n] Denominator[n],2])Pi

Table[ClosingAngle[n],{n,10}]

ArcLength

Table[ClosingAngle[n],{n,6}]

Table[ArcLength[Sin[n q],{q,0,ClosingAngle[n]}],{n,6}]

Table[2(Sqrt[(n^2)+1])EllipticE[((n^2)/((n^2)+1))],{n,6}]

Table[ClosingAngle[n],{n,(1/2),(5/2),1}]

Table[ArcLength[Sin[n q],{q,0,ClosingAngle[n]}],{n,(1/2),(5/2),1}]//FullSimplify

Table[2(Sqrt[(n^2)+1])EllipticE[((n^2)/((n^2)+1))],{n,(1/2),(5/2),1}]

PolarPlot[Sin[(1/2)q],{q,0,4Pi}]

ArcLength[Sin[2/3q],{q,0,2Pi}]

ClosingAngle[2/3]

4ArcLength[Sin[2/3q],{q,0,3Pi/2}]

2ArcLength[Sin[2/3q],{q,0,3Pi}]

ArcLength[Sin[2/3q],{q,0,6Pi}]

PolarPlot[Sin[(2/3)q],{q,0,3Pi/2}]

1 petal

Assuming[n>0,2a Integrate[(Sqrt[1-(1-(1/(n^2)))((Sin[t])^2)]),{t,0,Pi/2}]]

ArcLengthFunction

Assuming[a>0&&n>0&&t>0,ArcLength[a Sin[n t] {Cos[t],Sin[t]},{t, 0, t}]//FullSimplify]

(ConditionalExpression[a EllipticE[n t,1-(1/(n^2))], (-1+n) ((Csc[n t])^2)<0||(-1+n) (1-(n^2)+(n^2) ((Csc[n t])^2))>0])

Assuming[a>0&&n>1&&t>0,ArcLength[a Sin[n t] {Cos[t],Sin[t]},{t, 0, t}]]

Assuming[a>0&&0<n<1&&t>0,ArcLength[a Sin[n t] {Cos[t],Sin[t]},{t, 0, t}]]

Area

Table[ClosingAngle[n],{n,10}]

Even n

Assuming[n∈Integers&&n>0,MyArea[a Sin[n t],{t,0,2π}]]

Odd n

Assuming[n∈Integers&&n>0,MyArea[a Sin[n t],{t,0,π}]]

CartesianEquation

degree for n==p/q is p+q for p q odd and 2(p+q) for p q even

AlgebraicRose[n_,a_,{x_,y_}]:=Module[{p,q,c,s,u,eqn},
{p,q}=NumeratorDenominator[n];
eqn={
x-a TrigExpand[Sin[p u]]TrigExpand[Cos[q u]],
y-a TrigExpand[Sin[p u]]TrigExpand[Sin[q u]],
Cos[u]^2+Sin[u]^2-1
}/.{Cos[u]->c,Sin[u]->s};
First@GroebnerBasis[eqn,{x,y},{c,s},MonomialOrder->EliminationOrder]
]

TextGrid[Table[{n,AlgebraicRose[n,a,{x,y}]},{n,8}],Dividers->All]

Table[Piecewise[{{n+1,Mod[n,2]==1},{2(n+1),Mod[n,2]==0}},Missing["NotAvailable"]],{n,8}]

Table[
ContourPlot[Evaluate[AlgebraicRose[n,1,{x,y}]==0],{x,-1,1},{y,-1,1},MaxRecursion->5],{n,4}]

Can probably be done in "closed forms" for integer n as sums over terms using muliple-angle formulas:

TextGrid[Table[{n,AlgebraicRose[1/n,a,{x,y}]},{n,5}],Dividers->All]

Table[
ContourPlot[Evaluate[AlgebraicRose[1/n,1,{x,y}]==0],{x,-1,1},{y,-1,1},Exclusions->None,MaxRecursion->5],{n,4}]

Centroid

Table[ClosingAngle[n],{n,10}]

Even n

Assuming[Mod[n,2]==0&&n>0,Centroid[a Sin[n t],{t,0,2π}]]

Odd n

Assuming[Mod[n,2]==1&&n>0,Centroid[a Sin[n t],{t,0,π}]]

Curvature

FullSimplify[Curvature[a Sin[n t] {Cos[t],Sin[t]},t],a>0&&n>0]

ImplicitCurvature

FullSimplify[Curvature[a Sin[n q],q],a>0&&n>0]

InertiaTensor

Table[ClosingAngle[n],{n,10}]

Even n

Assuming[Mod[n,2]==0&&n>0&&a>0,AreaInertiaTensor[a Sin[n t],{t,0,2π}]]

Odd n

Assuming[Mod[n,2]==1&&n>0&&a>0,AreaInertiaTensor[a Sin[n t],{t,0,π}]]

NormalVector

FullSimplify[NormalVector[a Sin[n t] {Cos[t],Sin[t]},t],a>0&&n>0&&t>0]

ParametricEquations

ClosingAngle[2/3]

Block[{a=1,n=2/3},ParametricPlot[a Sin[n t] {Cos[t],Sin[t]},{t,0,6π}]]

Block[{a=1,n=(1/2)},ParametricPlot[a Sin[n t] {Cos[t],Sin[t]},{t,0,4π}]]

Block[{a=1,n=1},ParametricPlot[a Sin[n t] {Cos[t],Sin[t]},{t,0,π}]]

Block[{a=1,n=(3/2)},ParametricPlot[a Sin[n t] {Cos[t],Sin[t]},{t,0,4π}]]

Block[{a=1,n=2},ParametricPlot[a Sin[n t] {Cos[t],Sin[t]},{t,0,2Pi}]]

Block[{a=1,n=3},ParametricPlot[a Sin[n t] {Cos[t],Sin[t]},{t,0,π}]]

Block[{a=1,n=4},ParametricPlot[a Sin[n t] {Cos[t],Sin[t]},{t,0,2Pi}]]

PolarCurvature

FullSimplify[Curvature[a Sin[n q],q],a>0&&n>0]

PolarSlope

FullSimplify[Slope[a Sin[n q],q],a>0&&n>0]

PolarEquations

Block[{a=1,n=1},PolarPlot[a Sin[n t],{t,0,π}]]

Block[{a=1,n=2},PolarPlot[a Sin[n t],{t,0,2π}]]

Slope

FullSimplify[Slope[a Sin[n t] {Cos[t],Sin[t]},t],a>0&&n>0]

SpecialAffineCurvature

FullSimplify[SpecialAffineCurvature[Sin[n t] {Cos[t],Sin[t]},t],a>0&&n>0]

TangentVector

FullSimplify[TangentVector[a Sin[n t] {Cos[t],Sin[t]},t],a>0&&n>0&&t>0]

VectorLength

FullSimplify[VectorLength[a Sin[n t] {Cos[t],Sin[t]},t],a>0&&n>0&&t>0]