Quadrifolium

Author

Eric W. Weisstein
June 6, 2014

This notebook downloaded from http://mathworld.wolfram.com/notebooks/PlaneCurves/Quadrifolium.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/Quadrifolium.html.

©2014 Wolfram Research, Inc. except for portions noted otherwise

Plots

Polar

PolarPlot[Sin[2t],{t,0,2Pi},Ticks->None,PlotStyle->Red,ImageSize->150]

Implicit

ImplicitPlot[(x^2+y^2)^3==4x^2y^2,{x,-1,1},AxesOrigin->{0,0},
PlotStyle->Red,Ticks->None]

Parametric

ParametricPlot[Sin[2t]{Cos[t],Sin[t]},{t,0,2Pi},Ticks->None,PlotStyle->Red,ImageSize->150]

Equations

Eliminate[Append[Thread[{x,y}==a TrigExpand[Sin[2t]]{Cos[t],Sin[t]}],Sin[t]^2+Cos[t]^2==1],{Sin[t],Cos[t]}]

FullSimplify[%]

eqn=((((x^2)+(y^2)))^3)-4 (a^2) (x^2) (y^2);

Properties

curve=a Sin[2t]{Cos[t],Sin[t]};

Area

<<Graphics`InequalityGraphics`

Show[GraphicsArray[
Block[{$DisplayFunction=Identity},
{
InequalityPlot[(x^2+y^2)^3<4 x^2 y^2,{x},{y},Ticks->None,Prolog->{{Blue,Circle[{0,0},1]}},PlotRange->{{-1,1},{-1,1}}],
InequalityPlot[(x^2+y^2)^3>4 x^2 y^2&&x^2+y^2<1,{x},{y},Ticks->None,Fills->Yellow,PlotRange->{{-1,1},{-1,1}}]
}
]]]

(1/2)Integrate[(a Sin[2θ])^2,{θ,0,2π}]

2Integrate[(a Sin[2θ])^2,{θ,0,π/2}]

4Integrate[(a Sin[2θ])^2,{θ,0,π/4}]

Area[curve,{t,0,2π}]

<<Calculus`Integration`

Integrate[Boole[(x^2+y^2)^3<4 x^2 y^2],{x},{y}]

Integrate[Boole[(x^2+y^2)^3<4 x^2 y^2],{y},{x}]

NIntegrate[Boole[(x^2+y^2)^3<4x^2 y^2],{x},{y}]

Arc Length

ArcLength[curve,t,Assumptions->a>0&&0<t<2π]

Plot[EllipticE[2 t,(3/4)],{t,0,2π}]

Simplify[ArcLength[curve,{t,0,2π}],a>0]

Curvature

Parametric

FullSimplify[Curvature[curve,t],a>0&&0<t<2π]

Polar

FullSimplify[Curvature[a Sin[2q],q],a>0&&0<q<2π]

Implicit

SortBy[FullSimplify[Curvature[eqn,{x,y}],a>0&&(x|y)∈Reals],ByteCount]

ByteCount/@%

Inflection Points

InflectionPoints[eqn,{x,y}]//Union

Singular Points

SingularPoints[eqn,{x,y}]//Union

Slope

Parametric

Slope[a Sin[2 t] {Cos[t],Sin[t]},t]//FullSimplify

Polar

Slope[a Sin[2q],q]//FullSimplify

Implicit

Slope[(x^2+y^2)^3==4 a^2 x^2 y^2,{x,y}]//FullSimplify

ByteCount/@%

SpecialAffineCurvature

FullSimplify[SpecialAffineCurvature[curve,t],a>0&&0<t<2π]

Tangential Angle

FullSimplify[TangentialAngle[curve,t],0<t<2π]

g[t_]:=(π/2)+t-ArcTan[Cot[t]-Tan[t]]

Limit[g[t],t->π/2,Direction->#]&/@{-1,1}

Plot[(π/2)+t-ArcTan[Cot[t]-Tan[t]],{t,0,2π}]

FullSimplify[Curvature[curve,t] Sqrt[#.#&[D[curve,t]]]]

f[x_?NumericQ]:=NIntegrate[1+(8/(5+3 Cos[4 t])),{t,0,x}]

f[2π]

Plot[f[x],{x,0,2π}]

Plot[π+g[t]+π Floor[(t-π/2)2/π],{t,0,2π}]

FullSimplify[π+g[t]+π Floor[(t-π/2)2/π]]

Plot[Mod[(π/2)+t-ArcTan[Cot[t]-Tan[t]]+π Floor[((2 t)/π)],2π],{t,0,2π}]

Vector Properties

parm=a Sin[2 t] {Cos[t],Sin[t]};
assum=a>0&&0<t<2π;
xform={Abs[x_]^(n_/;Mod[n,2]==0):>x^n,Sqrt[x_^(n_/;Mod[n,2]==0)]:>Abs[x]^(n/2)};

VectorLength

Assuming[assum,FullSimplify[Norm[parm]/.xform]]/.xform

NormalVector

Assuming[assum,FullSimplify[NormalVector[parm,t]/.xform]]/.xform

TangentVector

Assuming[assum,FullSimplify[TangentVector[parm,t]/.xform]]/.xform