Pascal Matrix

Author

Eric W. Weisstein
March 5, 2008

This notebook downloaded from http://mathworld.wolfram.com/notebooks/LinearAlgebra/PascalMatrix.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/PascalMatrix.html.

©2008 Wolfram Research, Inc. except for portions noted otherwise

Additional Authors

PascalMatrix code by
Paul Abbott
19 Aug 2004

Code

PascalMatrixS[n_Integer?Positive]:=Array[Binomial[#1+#2-2,#2-1]&,{n,n}]

PascalMatrixS[n_Integer?Positive]:=NestList[Rest[FoldList[Plus,0,#]]&,Table[1,{i,n}],n-1]

PascalS[n_]:=Table[Binomial[i+j,i],{i,0,n-1},{j,0,n-1}]
PascalL[n_]:=Table[Binomial[i,j],{i,0,n-1},{j,0,n-1}]
PascalU[n_]:=Table[Binomial[j,i],{i,0,n-1},{j,0,n-1}]

Paul Abbott's definitions
19 Aug 2004

PascalMatrix[n_]:=Module[{i,j},Table[Binomial[i+j,i],{i,0,n-1},{j,0,n-1}]]
PascalMatrix[n_,1]:=(-1)^(Range[n]-1) CholeskyDecomposition[PascalMatrix[n]]
PascalMatrix[n_,2]:=Reverse/@PascalMatrix[n,1]

Examples

MatrixForm/@{PascalS[4],PascalL[4],PascalU[4]}

PascalMatrix[4]//TraditionalForm

LinearAlgebra`PascalMatrix[4]//TraditionalForm

Determinant

Det/@Table[PascalS[n],{n,10}]

Det/@Table[PascalL[n],{n,10}]

Det/@Table[PascalU[n],{n,10}]

S=LU

MatrixForm/@Table[PascalL[n].PascalU[n],{n,4}]

FullSimplify[Sum[Binomial[i,k]Binomial[j,k],{k,0,n-1}],(i|j|n)∈Integers&&i>0&&j>0&&n>1]

FullSimplify[Sum[Binomial[i,k]Binomial[j,k],{k,0,n-1}],(i|j|n)∈Integers&&0<i≤n-1&&0<j≤n-1&&n>1]

FunctionExpand[Binomial[i+j,i]]/.Gamma[x_]:>(x-1)!

FullSimplify[Sum[Binomial[i,k]Binomial[j,k],{k,0,n-1}],
(i|j|n)∈Integers]

FullSimplify[Sum[Binomial[i,k]Binomial[j,k],{k,0,n-1}],(i|j|n)∈Integers&&0<i<n&&0<j<n&&n>1]

Gamma[0]

Table[(i j! Gamma[i] HypergeometricPFQRegularized[{1,-i+n,-j+n},{1+n,1+n},1])/(Gamma[1+i-n] Gamma[1+j-n]),{n,3},{i,0,n-1},{j,0,n-1}]