Narayana Cow Sequence

Author

Eric W. Weisstein
February 14, 2025

This notebook downloaded from http://mathworld.wolfram.com/notebooks/IntegerSequences/NarayanaCowSequence.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/NarayanaCowSequence.html.

©2025 Wolfram Research, Inc. except for portions noted otherwise

Sequence

A000930

seq=Rest@Take[BFileSequence[000930],20]

Formulas

(Subscript[, 3])(Subscript[F, 2])(((1-n)/3),((2-n)/3),-(n/3);((1-n)/2),-(n/2);-(27/4))

Table[HypergeometricPFQ[{((1-n)/3),((2-n)/3),-(n/3)},{((1-n)/2),-(n/2)},-(27/4)],{n,20}]

seq=LinearRecurrence[{1,0,1},{1,1,2},20]

gf=FindGeneratingFunction[seq,x]

Series[gf,{x,0,20}]

FullSimplify[SeriesCoefficient[gf,{x,0,n}],n>0]

InputForm[%]

f1=-1-#1^2+#1^3&;
f2=-1+#1+31*#1^3&;
pos={1,2,3};

an=ToNumberField[Root[f2,#],Root[f1,pos[[#]]]]&/@Range[3]

coeffs=an[[All,-1]]

SameQ@@coeffs

RootSum[f1,Evaluate[((#)^(n+Range[Length[pos]]-1)).an[[1,2]]]&]

Table[-RootSum[-1-((#1)^2)+((#1)^3)&,3 ((#1)^(n+2))-11 ((#1)^(n+3))+2 ((#1)^(n+4))&]/31,{n,20}]

Table[-RootSum[1+((#1)^2)-((#1)^3)&,3 ((#1)^(n+2))-11 ((#1)^(n+3))+2 ((#1)^(n+4))&]/31,{n,20}]

Compositions

https://en.wikipedia.org/wiki/Supergolden_ratio#Narayana_sequence

The number of compositions of n into parts 1 and 3 is counted by the nth Narayana number.

InactivePlus[l_]:=If[Length[l]==1,l[[1]],Inactive[Plus][Sequence@@l]]

(compositions=Table[InactivePlus/@Sort@Flatten[Permutations/@IntegerPartitions[n,All,{1,3}],1],{n,8}])//Column

Length/@compositions

Ratio of terms

HypergeometricPFQ[{((1-n)/3),((2-n)/3),-(n/3)},{((1-n)/2),-(n/2)},-(27/4)]/.n->n+1

FullSimplify[((HypergeometricPFQ[{-(1/3)-(n/3),(1/3)-(n/3),-(n/3)},{-(1/2)-(n/2),-(n/2)},-(27/4)])/(HypergeometricPFQ[{((1-n)/3),((2-n)/3),-(n/3)},{((1-n)/2),-(n/2)},-(27/4)]))]

Limit[%,n->∞]

N[((HypergeometricPFQ[{-(1/3)-(n/3),(1/3)-(n/3),-(n/3)},{-(1/2)-(n/2),-(n/2)},-(27/4)])/(HypergeometricPFQ[{((1-n)/3),((2-n)/3),-(n/3)},{((1-n)/2),-(n/2)},-(27/4)]))/.n->100,20]

Limit[((-RootSum[1+((#1)^2)-((#1)^3)&,3 ((#1)^(n+3))-11 ((#1)^(n+4))+2 ((#1)^(n+5))&]/31)/(-RootSum[1+((#1)^2)-((#1)^3)&,3 ((#1)^(n+2))-11 ((#1)^(n+3))+2 ((#1)^(n+4))&]/31)),n->∞]

N[((-RootSum[1+((#1)^2)-((#1)^3)&,3 ((#1)^(n+3))-11 ((#1)^(n+4))+2 ((#1)^(n+5))&]/31)/(-RootSum[1+((#1)^2)-((#1)^3)&,3 ((#1)^(n+2))-11 ((#1)^(n+3))+2 ((#1)^(n+4))&]/31))/.n->100,20]

FunctionExpand[((-RootSum[1+((#1)^2)-((#1)^3)&,3 ((#1)^(n+3))-11 ((#1)^(n+4))+2 ((#1)^(n+5))&]/31)/(-RootSum[1+((#1)^2)-((#1)^3)&,3 ((#1)^(n+2))-11 ((#1)^(n+3))+2 ((#1)^(n+4))&]/31))]

Supergolden ratio:

psi=x/.ToRules[Reduce[x^3==x^2+1,x,Reals]]

N[%,20]

Limit[((3+n +4+n +5+n )/(2+n +2+n +2+n )),n->∞]