Leibniz Triangle

Author

Eric W. Weisstein
October 22, 2008

This notebook downloaded from http://mathworld.wolfram.com/notebooks/IntegerSequences/LeibnizHarmonicTriangle.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/LeibnizHarmonicTriangle.html.

©2008 Wolfram Research, Inc. except for portions noted otherwise

Recurrence

RSolve[{a[n,1]==1/n,a[n,k]==a[n-1,k-1]-a[n,k-1]},a[n,k],{n,k}]

FullSimplify[{a[n,k],a[n-1,k-1]-a[n,k-1]}/.a[n_,k_]:>1/k/Binomial[n,k]]

Subtract@@%//FullSimplify

FullSimplify[{a[n,k],a[n-1,k-1]-a[n,k-1]}/.a[n_,k_]:>(1/(n Binomial[n-1,k-1]))]

Subtract@@%//FullSimplify

LeafCount/@{(1/(n Binomial[-1+n,-1+k])),((Gamma[k] Gamma[1-k+n])/(Gamma[1+n]))}

Triangle

a[n_,1]:=1/n
a[n_,k_]:=a[n,k]=a[n-1,k-1]-a[n,k-1]

ColumnForm[Table[a[n,k],{n,10},{k,n}],Center]

ColumnForm[Table[(1/(k Binomial[n,k])),{n,10},{k,n}],Center]

ColumnForm[Table[(1/(n Binomial[n-1,k-1])),{n,10},{k,n}],Center]

Denominators

All Terms

Take[Union[Flatten[Table[1/a[n,k],{n,3,100},{k,2,n-1}]]],60]

2nd Diagonal

1/#[[2]]&/@Table[a[n,k],{n,2,40},{k,n}]

Row Sums

Fractions

Sum[(1/(k Binomial[n,k])),{k,n}]

Sum[(1/(n Binomial[n-1,k-1])),{k,n}]

rowsums=Table[Sum[(1/(k Binomial[n,k])),{k,n}],{n,10}]

Through[{Numerator,Denominator}[rowsums]]

Denominators

Sum[k Binomial[n,k],{k,n}]

Sum[n Binomial[n-1,k-1],{k,n}]

Table[(2^(-1+n)) n,{n,10}]