Mira Fractal

Author

Eric W. Weisstein
February 11, 2011

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Fractals/MiraFractal.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/MiraFractal.html.

©2011 Wolfram Research, Inc. except for portions noted otherwise

Code

F[x_,a_]:=a x+((2(1-a)(x^2))/(1+(x^2)))

MakeBoxes[label[a_,b_,x_,y_],TraditionalForm]:=GridBox[{{RowBox[{RowBox[{"a","==",MakeBoxes[a,TraditionalForm]}],",",RowBox[{"b","==",MakeBoxes[b,TraditionalForm]}]}]},
{RowBox[{"(",RowBox[{SubscriptBox["x","0"],",",SubscriptBox["y","0"]}],")","==","(",MakeBoxes[x,TraditionalForm],",",MakeBoxes[y,TraditionalForm],")"}]}}]

Mira[a_,b_,n_,x0_]:=Graphics[{PointSize[.005],Point[NestList[{x=b#[[2]]+F[#[[1]],a],-#[[1]]+F[x,a]}&,x0,n]]},PlotLabel->Style[ToString[label[a,b,x0[[1]],x0[[2]]],TraditionalForm],ShowStringCharacters->False]]

Graphics

GraphicsGrid[{
{Mira[.2,1,10000,{12,0}],Mira[.31,1,10000,{12,0}],Mira[.4,1,10000,{12,0}]},
{Mira[.7,.9998,10000,{9,0}],Mira[.7,.9998,10000,{12.1,0}],Mira[.7,.9998,10000,{15,0}]}
},Frame->All,ImageSize->400]

Show[Mira[.31,1,50000,{12,0}]/.PointSize[_]:>PointSize[.001],ImageSize->700]

GraphicsGrid[{{Mira[.7,.9998,10000,{9,0}],Mira[.7,.9998,10000,{12.1,0}]}},ImageSize->400]