Diophantine Equation—3rd Powers

Author

Eric W. Weisstein
September 18, 2024

This notebook downloaded from http://mathworld.wolfram.com/notebooks/DiophantineEquations/DiophantineEquation3rdPowers.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/DiophantineEquation3rdPowers.html.

©2024 Wolfram Research, Inc. except for portions noted otherwise

Waring's problem

A018888

Select[Range[500],PowersRepresentations[#,7,3]=={}&]

Select[Range[500],PowersRepresentations[#,8,3]=={}&]

Select[Range[500],PowersRepresentations[#,9,3]=={}&]

(A^3)+(B^3)==(C^3)+(D^3)

Reduce[a^3+b^3==c^3+d^3&&(a|b|c|d)∈Integers&&And@@(0<#<1000&)/@{a,b,c,d},{a,b,c,d}]

Do[
  list={};
  a=1;
  max=N[s^(1/3)];
  While[a<=max,
    b=(s-a^3)^(1/3);
    If[IntegerQ[b],
      list=Append[list,{a,b}]; max=b-1,
    ];
    a++;
  ];
  If[Length[list]>1,Print[s,". ",list]],
{s,1,50000}]

1729. {{1, 12}, {9, 10}}
4104. {{2, 16}, {9, 15}}
13832. {{2, 24}, {18, 20}}
20683. {{10, 27}, {19, 24}}
32832. {{4, 32}, {18, 30}}
39312. {{2, 34}, {15, 33}}
40033. {{9, 34}, {16, 33}}
46683. {{3, 36}, {27, 30}}

Form due to Ramanujan

Subtract@@{((((A^2)+7A B-9(B^2)))^3)+(((2(A^2)-4A B+12(B^2)))^3),(((2(A^2)+10(B^2)))^3)+((((A^2)-9A B-(B^2)))^3)}//Expand

(A^3)+(B^3)==(C^2)

Euler 1-parameter

rules={
A->3n^3+6n^2-n,
B->-3n^3+6n^2+n,
C->6n^2(3n^2+1)};

Simplify[A^3+B^3-C^2 /.rules]

l=Table[{A,B,C}/.rules,{n,100}];

Select[(g=GCD[#1^3,#2^3,#3^2];
{#1/g^(1/3),#2/g^(1/3),#3/g^(1/2)})&@@@l,FreeQ[#,Power]&]

Euler 2-parameter, GCD = 1

FullSimplify[(4m n(3m^2-3m n+n^2))^3+
((m-n)(3m-n)(3m^2+n^2))^3]

Factor[%]

PowerExpand[Sqrt[%]]

Simplify[
A^3+B^3-C^2 /. {
A->4m n(3m^2-3m n+n^2),
B->((m-n)(3m-n)(3m^2+n^2)),
C->(3 (m^2)-(n^2)) (9 (m^4)-18 (m^3) n+18 (m^2) (n^2)-6 m (n^3)+(n^4))
}]

l=Flatten[Table[{A,B,C}/.{
A->4m n(3m^2-3m n+n^2),
B->((m-n)(3m-n)(3m^2+n^2)),
C->(3 (m^2)-(n^2)) (9 (m^4)-18 (m^3) n+18 (m^2) (n^2)-6 m (n^3)+(n^4))
},{m,5},{n,5}],1]

Select[l,GCD[#[[1]]+#[[2]],#[[1]]^2-#[[1]]#[[2]]+#[[2]]^2]==1&]

Euler 2-parameter, GCD=3

FullSimplify[(3m^4+6m^2n^2-n^4)^3+
(-3m^4+6m^2n^2+n^4)^3]

Factor[%]

PowerExpand[Sqrt[%]]

Simplify[
A^3+B^3-C^2 /. {
A->(3m^4+6m^2n^2-n^4),
B->-3m^4+6m^2n^2+n^4,
C->6 m n (3 (m^4)+(n^4))}]

l=Flatten[Table[{A,B,C}/. {
A->(3m^4+6m^2n^2-n^4),
B->-3m^4+6m^2n^2+n^4,
C->6 m n (3 (m^4)+(n^4))
},{m,5},{n,5}],1]

Select[l,GCD[#[[1]]+#[[2]],#[[1]]^2-#[[1]]#[[2]]+#[[2]]^2]==3&]

GCD[8^3,4^3,24^2]

FactorInteger[%]

(A^3)+(B^3)+(C^3)==(D^3)

And@@Equal@@@Map[Plus@@#&,LikePowers[3,1,3]^3,{2}]

Equal@@@({Plus@@First[#],#[[-1,-1]]}&/@(Map[HoldForm,Reverse/@LikePowers[3,1,3],{-1}]^3))//ColumnForm//TraditionalForm

Piezas

Expand[Subtract@@{(3x^2+5x y-5y^2)^3+(4x^2-4x y+6y^2)^3+(5x^2-5x y-3y^2)^3,(6x^2-4x y+4y^2)^3}]

{3^3+4^3+5^3,6^3}

eqn=Subtract@@{(a x^2+v1 x y+b w y^2)^3+(b x^2-v1 x y+a w y^2)^3+(c x^2+v2 x y+d w y^2)^3+(d x^2-v2 x y+c w y^2)^3,(a^3+b^3+c^3+d^3)(x^2+w y^2)^3};

Expand[eqn/.{v1->-(c^2-d^2), v2->(a^2-b^2), w->(a+b)(c+d)}]