Sarnak's Constant

Author

Eric W. Weisstein
December 9, 2014

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Constants/SarnaksConstant.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/SarnaksConstant.html.

©2014 Wolfram Research, Inc. except for portions noted otherwise

Value

N[Times@@(1-((#+2)/((#)^3))&[Prime[Range[2,10^4]]]),20]//Timing

N[Times@@(1`20-((#+2)/((#)^3))&[Prime[Range[2,10^5]]]),20]//Timing

N[Times@@(1`30-((#+2)/((#)^3))&[Prime[Range[2,10^5]]]),30]//Timing

N[Times@@(1`50-((#+2)/((#)^3))&[Prime[Range[2,10^6]]]),50]//Timing

N[Times@@(1`50-((#+2)/((#)^3))&[Prime[Range[2,10^7]]]),50]//Timing

Including first term gives a factor of

1-((#+2)/((#)^3))&[2]

Times Another way

prod=N[1,25];
(Monitor[Do[prod*=With[{p=Prime[k]},1-((p+2)/(p^3))],{k,2,10^6}],{k,prod}];prod)//Timing

Series

Series[Log[1-((p+2)/(p^3))],{p,∞,10}]

SeriesCoefficient[Log[1-((p+2)/(p^3))],{p,∞,n}]//FullSimplify

c[n_]:=-((RootSum[-2-#1+((#1)^3)&,((#)^n)&])/n)

Table[RootSum[-2-#1+((#1)^3)&,((#)^n)&],{n,0,40}]

Table[c[n],{n,10}]//FullSimplify

Clear[a]

RSolve[{a[0]==0,a[1]==0,a[2]==2,a[n]==2a[n-3]+a[n-2]},a[n],n]//FullSimplify

2Exp[Sum[c[n]PrimeZetaP[n],{n,2,50}]]//N//Chop

Block[{$MaxExtraPrecision=1000},Accumulate[Table[c[n]PrimeZetaP[n]//N[#,50]&,{n,2,10}]]]//Chop

2Exp[Last[%]]

PrimeZetaP from Series

ser=Series[Log[1-((p+2)/(p^3))],{p,∞,2010}][[3]];

Block[{$MaxExtraPrecision=1000},
sums=2Exp[Accumulate[N[Table[ser[[k]] PrimeZetaP[k+1],{k,2000}],500]]]
];//Timing

ListPlot[Log10[Abs[Last[sums]-sums]]]

Abs[sums[[-1]]-sums[[-2]]]

N[Last[sums],-Log10[Abs[sums[[-1]]-sums[[-2]]]]-2]

-Log10[Abs[sums[[-1]]-sums[[-2]]]]-2