Quadratic Class Number Constant

Author

Eric W. Weisstein
December 9, 2014

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Constants/QuadraticClassNumberConstant.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/QuadraticClassNumberConstant.html.

©2014 Wolfram Research, Inc. except for portions noted otherwise

Value

Times@@(1`20-(1/(((#)^2)(#+1)))&[Prime[Range[5 10^4]]])

Times Another way

prod=N[1,25];
(Monitor[Do[prod*=With[{p=Prime[k]},1-(1/((p^2)(p+1)))],{k,10^6}],{k,prod}];prod)//Timing

Series

Series[Log[1-(1/((p^2)(p+1)))],{p,∞,10}]

SeriesCoefficient[Log[1-(1/((p^2)(p+1)))],{p,∞,n}]//FullSimplify

c[n_]:=(1/n)((((-1))^n)+Root[1-#1+((#1)^3)&,1] ((Root[-1+((#1)^2)+((#1)^3)&,1])^(1+n))+Root[1-#1+((#1)^3)&,2] ((Root[-1+((#1)^2)+((#1)^3)&,2])^(1+n))+Root[1-#1+((#1)^3)&,3] ((Root[-1+((#1)^2)+((#1)^3)&,3])^(1+n)))

Table[c[n],{n,10}]//FullSimplify

Exp[Sum[c[n]PrimeZetaP[n],{n,2,50}]]//N//Chop

Block[{$MaxExtraPrecision=1000},Accumulate[Table[c[n]PrimeZetaP[n]//N[#,50]&,{n,2,10}]]]//Chop

Exp[Last[%]]

PrimeZetaP from Series

ser=Series[Log[1-(1/((p^2)(p+1)))],{p,∞,2010}][[3]];

Block[{$MaxExtraPrecision=1000},
sums=Exp[Accumulate[N[Table[ser[[k]] PrimeZetaP[k+2],{k,2000}],500]]]
];//Timing

ListPlot[Log10[Abs[Last[sums]-sums]]]

Abs[sums[[-1]]-sums[[-2]]]

N[Last[sums],-Log10[Abs[sums[[-1]]-sums[[-2]]]]-2]

-Log10[Abs[sums[[-1]]-sums[[-2]]]]-2