Feller-Tornier Constant

Author

Eric W. Weisstein
December 9, 2014

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Constants/Feller-TornierConstant.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/Feller-TornierConstant.html.

©2014 Wolfram Research, Inc. except for portions noted otherwise

Monte Carlo

With[{max=10^8,n=10^6},Count[Mod[Length[DeleteCases[Last/@FactorInteger[#],1]],2]&/@Table[Random[Integer,{1,max}],{n}],0]/n]//N[#,10]&//Timing

Value

Exact

(1/2)+(1/2)Product[1-(2/((Prime[n])^2)),{n,Infinity}]

Numeric

(1/2)(1+SequenceLimit[FoldList[Times,1,N[Table[1-(2/((Prime[n])^2)),{n,10000}],100]]])//Timing

(1/2)(1+SequenceLimit[FoldList[Times,1,Table[1`200-(2/((Prime[n])^2)),{n,10000}]],WynnDegree->2])//Timing

(1/2)(1+SequenceLimit[FoldList[Times,1,N[Table[1-(2/((Prime[n])^2)),{n,20000}],200]]])//Timing

(1/2)(1+Times@@Table[1`100-(2/((Prime[n])^2)),{n,10^6}])//Timing

Times Another way

prod=N[1,25];
(Monitor[Do[prod*=With[{p=Prime[k]},1-(2/(p^2))],{k,10^6}],{k,1/2(1+prod)}];1/2(1+prod))//Timing

Series

Series[Log[1-(2/(p^2))],{p,∞,10}]

SeriesCoefficient[Log[1-(2/(p^2))],{p,∞,n}]//FullSimplify

c[n_]:=-(((2^(n/2)) (1+(((-1))^n)))/n)

Table[c[n],{n,15}]//FullSimplify

(1/2)(1+Exp[Sum[-(((2^(n/2)) (1+(((-1))^n)))/n)PrimeZetaP[n],{n,2,50}]])//N

(1/2)(1+Exp[Sum[-(((2^(n/2)) (1+(((-1))^n)))/n)PrimeZetaP[n],{n,2,50,2}]])//N

(1/2)(1+Exp[-Sum[(((2^n) )/n)PrimeZetaP[2n],{n,50}]])//N

Sum[(((2^n) )/n)PrimeZetaP[2n],{n,∞}]

Sum[(((2^n) )/n)PrimeZetaP[2n],{n,1000}]//N

(1/2)(1+Exp[-%])

Block[{$MaxExtraPrecision=1000},Accumulate[Table[c[n]PrimeZetaP[n]//N[#,50]&,{n,2,20}]]]//Chop

(1/2)(1+Exp[Last[%]])

PrimeZetaP from Series

ser=Series[Log[1-(2/(p^2))],{p,∞,2010}][[3]];

Block[{$MaxExtraPrecision=1000},
sums=Exp[Accumulate[N[Table[ser[[k]] PrimeZetaP[k+1],{k,2000}],300]]]
];//Timing

ListPlot[Log10[Abs[Last[sums]-sums]]]

sums[[-1]]

Abs[sums[[-1]]-sums[[-2]]]

N[(1/2)(1+Last[sums]),-Log10[Abs[sums[[-1]]-sums[[-2]]]]-2]

-Log10[Abs[sums[[-1]]-sums[[-2]]]]-2