Alladi-Grinstead Constant

Author

Eric W. Weisstein
November 30, 2023

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Constants/Alladi-GrinsteadConstant.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/Alladi-GrinsteadConstant.html.

©2023 Wolfram Research, Inc. except for portions noted otherwise

Code

FactorialPartitions[n_]:=Module[{f=FactorInteger[n!]},
Union[Sort/@Flatten/@Flatten[Outer[List,Sequence@@(#1^Partitions[#2]&@@@f),1],Length[f]-1]]
]
FactorialPartitions[n_,k_]:=Module[{f=FactorInteger[n!]},
Select[FactorialPartitions[n],Length[#]==k&]
]
m[n_]:=Max[First/@FactorialPartitions[n,n]]
alpha[n_]:=Log[m[n]]/Log[n]

Number of Factorial Partitions of n

A085288

Length/@(FactorialPartitions/@Range[2,24])//Timing

Number of Factorial Partitions of n of Length n

A085289

Length/@(FactorialPartitions[#,#]&/@Range[2,24])//Timing

m(n) and α(n)

A085290

(ms=Table[m[n],{n,2,25}])//Timing

FullSimplify[Table[alpha[n],{n,2,10}]]

Ratio

ratio=MapIndexed[Log[#1]/Log[#2[[1]]+3]&,Drop[ms,2]]//FullSimplify

N[ratio]

ListStepPlot[ratio,AxesLabel->{n,α[n]}]

Integrals

(∫_0^1)log((Floor[(1/x)]))dx

https://math.stackexchange.com/questions/3454128/evaluating-int-01-ln-left-lfloor-frac1x-right-rfloor-dx

Integrate[Log[Floor[(1/x)]],{x,0,1}]

NIntegrate[Log[Floor[(1/x)]],{x,0,1},WorkingPrecision->20]

N[%]

Sums

(∑_(k=2)^∞)(1/k)ln((k/(k-1)))

Sum[Log[k/(k-1)]/k,{k,2,Infinity}]//Timing

(∑_n^∞)(((Zeta[n+1])-1)/n)

Sum[((Zeta[n+1]-1)/n),{n,∞}]//Timing

Transformation of Sum

Series[Log[k/(k-1)]/k,{k,Infinity,20}]

1/n Sum[1/k^(n+1),{k,2,∞}]

Sum[(-1+Zeta[1+n])/n,{n,∞}]

Plot[(-1+Zeta[1+n])/n,{n,1,10},PlotStyle->Red]

LogPlot[(-1+Zeta[1+n])/n,{n,1,100},PlotStyle->Red]

LogPlot[(-1+Zeta[1+n])/n,{n,1,50},PlotStyle->Red,WorkingPrecision->20]

N[Sum[(-1+Zeta[1+n])/n,{n,1000}],110]

c=N[Sum[(-1+Zeta[1+n])/n,{n,1500}],110]

(c=N[Sum[(-1+Zeta[1+n])/n,{n,5000}],1000])//Timing

(c=N[Sum[(-1+Zeta[1+n])/n,{n,7000}],1000])//Timing

Exp[c-1]

Precision[%]

NSum[(-1+Zeta[1+n])/n,{n,∞},PrecisionGoal->200,WorkingPrecision->1000]

Relation between α(∞) and c

Exp[0.78853056591150896106028681013193222386`21.3117173184497-1]