Buchstab Function

Author

Eric W. Weisstein
April 15, 2004

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Combinatorics/BuchstabFunction.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/BuchstabFunction.html.

©2005 Wolfram Research, Inc. except for portions noted otherwise

Additional Authors

Code for setting up and solving the delay differential equation by
Michael Trott
June 13, 2003

Code

BuchstabFunctionList=FixedPointList[{(*integration interval start point*)
#[[1]]+1,NDSolve[{z w'[z]+w[z]==#[[2]][[1,1,2]][z-1],(*solve differential equation*)
w[#[[1]]+1]==#[[2]][[1,1,2]][#[[1]]+1]},w,
{z,#[[1]]+1,#[[1]]+2},
WorkingPrecision->40,MaxSteps->10^4,PrecisionGoal->20,AccuracyGoal->20]}&,
(*solution in interval[1,2]*)
{1,{{w[z]->(1/#&)}}},
(*solve until values at endpoints coincide*)
SameTest->((#1[[2,1,1,2]][#1[[1]]+1]==#2[[2,1,1,2]][#2[[1]]+1])&)];

BuchstabFunction[x_]:=BuchstabFunctionList[[IntegerPart[x]]][[2,1,1,2]][x]

Check

Should be 1 for 1<u<2

Table[BuchstabFunction[u]u,{u,1,2,.1}]

Satisfies ((u ω (u)))'=ω (u-1) for ω>2

With[{eps=10^-10},
Table[(BuchstabFunction[(u+eps)](u+eps)-BuchstabFunction[u]u)/eps-BuchstabFunction[u-1],{u,2,3,.1}]
]

Asymptotic Valie

Exp[-EulerGamma]//N

BuchstabFunction[4.]

Plot

<<Graphics`Colors`

Plot[BuchstabFunction[x],{x,1,4},PlotRange->All,PlotStyle->Red,AxesLabel->TraditionalForm/@{u,ω[u]},Prolog->{{Blue,Dashing[{.02}],Line[{{-20,Exp[-EulerGamma]},{20,Exp[-EulerGamma]}}]}}
]