Tautochrone Problem

Author

Eric W. Weisstein
April 15, 2004

This notebook downloaded from http://mathworld.wolfram.com/notebooks/CalculusofVariations/TautochroneProblem.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/TautochroneProblem.html.

©2005 Wolfram Research, Inc. except for portions noted otherwise

Code

cycloid[a_,b_][t_]:={a t-b Sin[t],a-b Cos[t]}

cycloidarc[a_][{t1_,t2_}]:=Module[{t},ParametricPlot[{a(t+Sin[t]),-2a Sin[t/2]^2},{t,t1,t2},DisplayFunction->Identity,Ticks->None,Axes->False][[1]]]

evolute[cycloid[a_,a_]][t_]:={a(t+Sin[t]),-2a Sin[t/2]^2}

Period

Original Form

FullSimplify[ Integrate[Sqrt[2a^2(1-Cos[θ])/(2a g(Cos[θ0]-Cos[θ]))],{θ,θ0,π}],0<θ0<Pi/2]

FullSimplify[I (Sqrt[(a/g)]) Log[(1+Cos[θ0])(I (Sqrt[2]) Cos[((θ0)/2)])^(-2)]]

Sin transformed

FullSimplify[Sqrt[a/g]Integrate[Sqrt[2]Sin[θ/2]/Sqrt[Cos[θ0]-Cos[θ]],{θ,θ0,π}],0<θ0<Pi/2]

FullSimplify[%]

FunctionExpand[ ArcSin[Sec[θ0]]]

FullSimplify[Integrate[Sqrt[Cos[θ0]/(1-u)/(1+u Cos[θ0])],{u,0,1}]]

FullSimplify[Log[(2+((I (-1+Cos[θ0]))/(Sqrt[Cos[θ0]])))/(-((I (1+Cos[θ0]))/(Sqrt[Cos[θ0]])))]]

In u variable

-2 Sqrt[a/g]Integrate[1/Sqrt[1-u^2],{u,1,0}]

Animation

movie=Table[ParametricPlot[{cycloid[-1,-1][t],evolute[cycloid[-1,-1]][t]}//Evaluate,{t,-0.001,2Pi+0.001},AspectRatio->Automatic,DisplayFunction->Identity,PlotStyle->{Dashing[{.02,.02}],{}},Axes->None,Epilog->{{Thickness[.015],cycloidarc[-1][{a,Pi}],Line[{cycloid[-1,-1][a],evolute[cycloid[-1,-1]][a]}]},PointSize[.03],Point[cycloid[-1,-1][a]]}],{a,-0.001,2Pi+0.001,Pi/20}];

<<Utilities`GIF`;

Export[gifs<>"tautochr.gif",Show[#,DisplayFunction->$DisplayFunction]&/@Join[movie,Reverse[movie]]]//Timing

Still Frames

Show[GraphicsArray[Partition[Table[
	Show[ParametricPlot[
		{cycloid[-1,-1][t],
		evolute[cycloid[-1,-1]][t]}//Evaluate,
	{t,-0.001,2Pi+0.001},
	AspectRatio->Automatic,DisplayFunction->Identity,
	PlotStyle->{Dashing[{.04,.04}],{}},Axes->None],
	Graphics[{{Thickness[.03],cycloidarc[-1][{a,Pi}],
	Line[{cycloid[-1,-1][a],evolute[cycloid[-1,-1]][a]}]},
	PointSize[.07],Point[cycloid[-1,-1][a]]}]
	],
	{a,-0.001,2Pi+0.001,2Pi/7}
],4]]]