Euler Sum

Author

Eric W. Weisstein
January 26, 2008

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Calculus/EulerSum.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/EulerSum.html.

©2008 Wolfram Research, Inc. except for portions noted otherwise

Initialization

Off[General::"spell1",General::"spell"]

Code

EulerSumSH[m_,n_]:=Sum[HarmonicNumber[k]^m/(k+1)^n,{k,Infinity}]
EulerSumSA[m_,n_]:=Sum[((1/2)*(-1)^k(HarmonicNumber[(1/2)*(-1+k)]-HarmonicNumber[k/2])+Log[2])^m (k+1)^(-n),{k,Infinity}]
EulerSumAH[m_,n_]:=Sum[HarmonicNumber[k]^m (-1)^(k+1)(k+1)^(-n),{k,Infinity}]
EulerSumAA[m_,n_]:=Sum[(((1/2)*(-1)^k*(HarmonicNumber[(1/2)*(-1+k)]-HarmonicNumber[k/2])+Log[2])^m(-1)^(k+1))(k+1)^(-n),{k,Infinity}]
EulerSumSigmaH[m_,n_]:=Sum[HarmonicNumber[k,m](k+1)^(-n),{k,Infinity}]
EulerSumSigmaA[m_,n_]:=Sum[((-2+2^m)*Zeta[m]+(-1)^k*(Zeta[m,1+k/2]-Zeta[m,(1+k)/2]))/(2^m*(k+1)^(n)),{k,Infinity}]
EulerSumAlphaH[m_,n_]:=Sum[(HarmonicNumber[k,m]*(-1)^(k+1))(k+1)^(-n),{k,Infinity}]
EulerSumAlphaA[m_,n_]:=Sum[(((-2+2^m)*Zeta[m]+(-1)^k*(Zeta[m,1+k/2]-Zeta[m,(1+k)/2]))*(-1)^(k+1))/(2^m*(k+1)^(n)),{k,Infinity}]

EulerSumSH[2,2]

Table of Values

eulerSumSH[2,2]:=3/2 Zeta[4]+1/2 Zeta[2]^2
eulerSumSH[2,4]:=37/22680 Pi^6-Zeta[3]^2
eulerSumSH[3,2]:=15/2 Zeta[5]+Zeta[2] Zeta[3]
eulerSumSH[3,3]:=-33/16 Zeta[6]+2 Zeta[3]^2
eulerSumSH[3,4]:=119/16 Zeta[7]-33/4 Zeta[3]Zeta[4]+2 Zeta[2]Zeta[5]
eulerSumSH[3,6]:=197/24 Zeta[9]-33/4 Zeta[4]Zeta[5]-37/8 Zeta[3]Zeta[6]+Zeta[3]^3+3Zeta[2]Zeta[7]
eulerSumSH[4,2]:=859/24 Zeta[6]+3Zeta[3]^2
eulerSumSH[4,3]:=-109/8 Zeta[7]+37/2 Zeta[3] Zeta[4]-5 Zeta[2] Zeta[5]
eulerSumSH[4,5]:=-29/2 Zeta[9]+37/2 Zeta[4] Zeta[5]+33/4 Zeta[3]Zeta[6]-8/3 Zeta[3]^3-7 Zeta[2] Zeta[7]
eulerSumSH[5,2]:=1855/16 Zeta[7]+33 Zeta[3]Zeta[4]+57/2 Zeta[2] Zeta[5]
eulerSumSH[5,4]:=890/9 Zeta[9]+66 Zeta[4] Zeta[5]-4295/24 Zeta[3] Zeta[6]-5 Zeta[3]^3+265/8 Zeta[2] Zeta[7]
eulerSumSH[6,3]:=-3073/12 Zeta[9]-243 Zeta[4] Zeta[5]+2097/4 Zeta[3] Zeta[6]+67/3 Zeta[3]^3-651/8 Zeta[2] Zeta[7]
eulerSumSH[7,2]:=134701/36 Zeta[9]+15697/8 Zeta[4] Zeta[5]+29555/24 Zeta[3] Zeta[6]+56 Zeta[3]^3+3287/4 Zeta[2]Zeta[7]

eulerSumSA[2,2]:=6PolyLog[4,1/2]+1/4 Log[2]^4-29/8 Zeta[4]+3/2 Zeta[2] Log[2]^2
eulerSumSA[2,3]:=4PolyLog[5,1/2]-1/30 Log[2]^5-17/32 Zeta[5]-11/8 Zeta[4]Log[2]+7/4 Zeta[3] Log[2]^2+1/3 Zeta[2] Log[2]^3-3/4 Zeta[2] Zeta[3]
eulerSumSA[3,2]:=-24PolyLog[5,1/2]+6Log[2]PolyLog[4,1/2]+9/20 Log[2]^5+659/32 Zeta[5]-285/16 Zeta[4]Log[2]+5/2 Zeta[2] Log[2]^3+1/2 Zeta[2] Zeta[3]

eulerSumAH[2,2]:=-2PolyLog[4,1/2]-1/12 Log[2]^4+99/48 Zeta[4]-7/4 Zeta[3] Log[2]+1/2 Zeta[2] Log[2]^2
eulerSumAH[2,3]:=-4PolyLog[5,1/2]-4 Log[2]PolyLog[4,1/2]-2/15 Log[2]^5+107/32 Zeta[5]-7/4 Zeta[3] Log[2]^2+2/3 Zeta[2] Log[2]^3+3/8 Zeta[2] Zeta[3]
eulerSumAH[3,2]:=6PolyLog[5,1/2]+6 Log[2]PolyLog[4,1/2]+1/5 Log[2]^5-33/8 Zeta[5]+21/8 Zeta[3] Log[2]^2-Zeta[2] Log[2]^3-15/16 Zeta[2] Zeta[3]

eulerSumAA[1,3]:=Log[2]^4/12-Zeta[4]/2-Zeta[2]Log[2]^2/2+2PolyLog[4,1/2]
eulerSumAA[2,2]:=-4 PolyLog[4,1/2]-1/6 Log[2]^4+37/16 Zeta[4]+7/4 Zeta[3] Log[2]-2 Zeta[2] Log[2]^2
eulerSumAA[2,3]:=4 Log[2] PolyLog[4,1/2]+1/6 Log[2]^5-79/32 Zeta[5]+11/8 Zeta[4] Log[2]-Zeta[2] Log[2]^3+3/8 Zeta[2] Zeta[3]
(* Wrong in Bailey, Borwein, and Girgensohn *)
(*
eulerSumAA[3,2]:=30 Log[5,1/2]-1/4 Log[2]^5-1813/64 Zeta[5]+285/16 Zeta[4] Log[2]+21/8 Zeta[3] Log[2]^2-7/2 Zeta[2] Log[2]^3+3/4 Zeta[2] Zeta[3]
*)

eulerSumSigmaH[2,2]:=1/2 Zeta[2]^2-1/2 Zeta[4]
eulerSumSigmaH[2,4]:=-6Zeta[6]+8/3 Zeta[2] Zeta[4]+Zeta[3]^2

eulerSumAlphaA[2,4]:=3/4Zeta[3]^2-97/96Zeta[6]

1

Symbolic Expressions

eulerSumSH[1,n_]:=1/2 n Zeta[n+1]-1/2 Sum[Zeta[n-k]Zeta[k+1],{k,1,n-2}]
eulerSumSigmaH[1,n_]:=eulerSumSH[1,n]
eulerSumSH[2,n_]:=1/3 n(n+1)Zeta[n+2]+Zeta[2]Zeta[n]-1/2 n Sum[Zeta[n-k]Zeta[k+2],{k,0,n-2}]+1/3 Sum[Zeta[n-k]Sum[Zeta[j+1]Zeta[k+1-j],{j,1,k-1}],{k,2,n-2}]+eulerSumSigmaH[2,n]
eulerSumSigmaH[2,m_?OddQ]:=Module[{n=(m+1)/2},-1/2(2n^2+n+1)Zeta[2n+1]+Zeta[2]Zeta[2n-1]+Sum[2k Zeta[2k+1]Zeta[2n-2k],{k,1,n-1}]]
eulerSumSigmaH[m_?OddQ,n_?EvenQ]:=1/2(Binomial[m+n,m]-1)Zeta[m+n]+Zeta[m]Zeta[n]-Sum[(Binomial[2j-2,m-1]+Binomial[2j-2,n-1])Zeta[2j-1]Zeta[m+n-2j+1],{j,1,m+n}]
eulerSumSigmaH[m_?EvenQ,n_?OddQ]:=-1/2(Binomial[m+n,n]+1)Zeta[m+n]+Sum[(Binomial[2j-2,m-1]+Binomial[2j-2,n-1])Zeta[2j-1]Zeta[m+n-2j+1],{j,1,m+n}]

Examples

CheckSums[euler0_]:=Module[{indx,v1,v2,sym1,sym2,euler,dif},
euler="EulerSum"<>euler0;
sym1=ToExpression[euler];
sym2=ToExpression[ToLowerCase[StringTake[euler,1]]<>StringDrop[euler,1]];
{indx={#[[1,1,1]],#[[1,1,2]]},v1=sym1@@indx,v2=#[[1,1]],dif=Simplify[v1-v2];Style[dif,If[dif===0,Green,Red]]}&/@DownValues[sym2//Evaluate]
]

(Subscript[s, h])(m,n)

V5

EulerSumSH[m,n]

V7

EulerSumSH[m,n]

Print[{#,EulerSumSH@@#//Timing}]&/@{{2,2},{2,4},{3,2},{3,3},{3,4},{3,6},{4,2},{4,3},{4,5},{5,2},{5,4},{6,3},{7,2}};

Check

CheckSums["SH"]//Column//TraditionalForm

(Subscript[s, a])(m,n)

EulerSumSA[m,n]

Print[{#,EulerSumSH@@#//Timing}]&/@{{2,2},{2,3},{3,2}};

Check

CheckSums["SA"]//Column//TraditionalForm

SA=First/@(First/@DownValues[eulerSumSA]/.eulerSumSA:>List)

sum2=eulerSumSA@@@SA//N

sum1=N[EulerSumSA@@@SA]

With[{n=2,m=2},NSum[(((1+k))^(-n)) ((((1/2) (((-1))^k) (HarmonicNumber[(1/2) (-1+k)]-HarmonicNumber[(k/2)])+Log[2]))^m),{k,∞}]
]

With[{n=2,m=2},NSum[(((1+k))^(-n)) ((((1/2) (((-1))^k) (HarmonicNumber[(1/2) (-1+k)]-HarmonicNumber[(k/2)])+Log[2]))^m),{k,∞},PrecisionGoal->10,Method->Fit,NSumTerms->200,NSumExtraTerms->200]
]

With[{n=2,m=2},Sum[(((1+k))^(-n)) ((((1/2) (((-1))^k) (HarmonicNumber[(1/2) (-1+k)]-HarmonicNumber[(k/2)])+Log[2]))^m),{k,5000}]//N
]

eulerSumSA[2,2]//InputForm

With[{m=3,n=2},NSum[(((1+k))^(-n)) ((((1/2) (((-1))^k) (HarmonicNumber[(1/2) (-1+k)]-HarmonicNumber[(k/2)])+Log[2]))^m),{k,∞}]
]

With[{m=3,n=2},NSum[(((1+k))^(-n)) ((((1/2) (((-1))^k) (HarmonicNumber[(1/2) (-1+k)]-HarmonicNumber[(k/2)])+Log[2]))^m),{k,∞},PrecisionGoal->10,Method->Fit,NSumTerms->200,NSumExtraTerms->200]
]

eulerSumSA[3,2]//InputForm

N[%]

(Subscript[a, h])(m,n)

EulerSumAH[m,n]

CheckSums["AH"]//Column//TraditionalForm

AH=First/@(First/@DownValues[eulerSumAH]/.eulerSumAH:>List)

sum2=eulerSumAH@@@AH//N

sum1=N[EulerSumAH@@@AH]

(Subscript[a, a])(m,n)

EulerSumAA[m,n]

CheckSums["AA"]//Column//TraditionalForm

AA=First/@(First/@DownValues[eulerSumAA]/.eulerSumAA:>List)

sum2=eulerSumAA@@@AA//N

sum1=N[EulerSumAA@@@AA]

With[{m=2,n=2},NSum[(((-1))^(1+k)) (((1+k))^(-n)) ((((1/2) (((-1))^k) (HarmonicNumber[(1/2) (-1+k)]-HarmonicNumber[(k/2)])+Log[2]))^m),{k,∞}]]

With[{m=2,n=2},Sum[(((-1))^(1+k)) (((1+k))^(-n)) ((((1/2) (((-1))^k) (HarmonicNumber[(1/2) (-1+k)]-HarmonicNumber[(k/2)])+Log[2]))^m),{k,1000}]]//N

(Subscript[σ, h])(m,n)

EulerSumSigmaH[m,n]

CheckSums["SigmaH"]//Column//TraditionalForm

SigmaH=First/@(First/@DownValues[eulerSumSigmaH]/.eulerSumSigmaH:>List)

sum2=eulerSumSigmaH@@@SigmaH//N

sum1=N[EulerSumSigmaH@@@SigmaH]

eulerSumSigmaH[3,2]

(Subscript[σ, a])(m,n)

EulerSumSigmaA[m,n]

CheckSums["SigmaA"]//Column//TraditionalForm

SigmaA=First/@(First/@DownValues[eulerSumSigmaA]/.eulerSumSigmaA:>List)

αh(m,n)

EulerSumAlphaH[m,n]

CheckSums["AlphaH"]//Column//TraditionalForm

AlphaH=First/@(First/@DownValues[eulerSumAlphaH]/.eulerSumAlphaH:>List)

αa(m,n)

EulerSumAlphaA[m,n]

CheckSums["AlphaA"]//Column//TraditionalForm

AlphaA=First/@(First/@DownValues[eulerSumAlphaA]/.eulerSumAlphaA:>List)

sum1=eulerSumAlphaA@@@AlphaA//N

sum1=N[EulerSumAlphaA@@@AlphaA]